2 Tabellenblätter als PDF speichern

[HajoHH]

Moin,Moin,
bin leider nicht sonderlich in VBA bewandert. Ich habe eine Exceldatei mit mehreren Tabellenblättern. Bisher musste ich immer 1 davon als PDF speichern, was auch alles super funktioniert. Nun muss ich allerdings noch ein 2. Blatt als PDF speichern, welches "Stundenzettel" heisst. habe schon einiges versucht, aber keine Lösung gefunden. Hier mein bisheriges Makro.

Code:

Sub Schaltfläche2_SpeichernUnter1()
   With ThisWorkbook.Worksheets("Erfassung")
       .ExportAsFixedFormat _
           Type:=xlTypePDF, _
           Filename:="C:\JH Buchhaltung\Aufträge\" & .Range("E4").Text & " " & .Range("B4").Text & " " & .Range("B8").Text & ".pdf", _
           Quality:=xlQualityStandard, _
           IncludeDocProperties:=True, _
           IgnorePrintAreas:=False, _
           OpenAfterPublish:=False
   End With
End Sub

[Kl@us-M.]

Moin moin zurück,

sollen die beiden Blätter als ein pdf-Dokument gespeichert werden (wenn ja, unter welchem Namen) oder als zwei getrennte pdf's ?

[HajoHH]

Hallo,
zusammenfügen geht wohl nur wenn ich zusätzliche Software beanspruche. Es kann auch getrennt gespeichert werden, jedoch im selben ordner. Da wäre dass Problem mit der Namensgebung. Wie ist mir eigentlich egal, Hauptsache, beide blätter sind als pdf in dem ordner dem es zugewiesen wird

[WillWissen]

Hallo Hajo,

zusammenfügen geht wohl nur wenn ich zusätzliche Software beanspruche.

mit VBA kann ich dir nicht weiterhelfen. Allerdings verstehe ich dein Problem nicht ganz. Wenn du in einer Datei von z. B. 10 Tabellenblätter die beiden Blätter Tab3 und Tab6 als PDF brauchst, reicht es doch, weinn du beide Tabellenreiter markierst (mit gedrückter STRG-Taste) und unter "Speichern unter" einen Namen wählst und als Dateityp PDF. Es werden dann exakt diese beiden Blätter in einer Datei abgespeichert.

Ich habe den gesamten Vorgang einmal mit dem Makrorekorder aufgezeichnet - das könntest du auch machen und zum Verbessern und Verallgemeinern hier einstellen.

So sieht es bei mir aus:

Sub TestZweiTabAlsPDF()
'
' TestZweiTabAlsPDF Makro
'

'
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        "D:\01-Meine Daten\Forum\Testmappen\erstellte Testmappen\TestPDF.pdf", Quality _
        :=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
        OpenAfterPublish:=True
    ActiveWindow.SmallScroll Down:=-21
    Sheets("Versuch A").Select
    Range("D22").Select
    Sheets("Versuch B").Select
End Sub

[HajoHH]

mein makro ist auf einen button hinterlegt. Bei Ausführung, wird bisher, dass Blatt unter einem neuen, aus verschiedener Zellen bestehenden, Namen erstellt. Diese Automatisierung möchte ich beibehalten.

[mumpel]

Hallo!

1. Bitte kein Crossposting.

2. Kopiere die beiden Tabellenblätter einfach in eine neue Datrei und speichere dann die Datei als PDF.

Sub Schaltfläche2_SpeichernUnter1()

Dim arrSheet As Variant
Dim strDatei As String

With ThisWorkbook
    With .Sheets("Erfassung")
         strDatei = "C:\JH Buchhaltung\Aufträge\" & .Range("E4").Text & _
                    " " & .Range("B4").Text & " " & .Range("B8").Text & _
                    ".pdf"
    End With
   .Sheets(Array("Tabelle1", "Tabelle3")).Copy
End With

With ActiveWorkbook
        .ExportAsFixedFormat Type:=xlTypePDF, Filename:=strDatei, _
                             Quality:=xlQualityStandard, _
                             IncludeDocProperties:=True, _
                             IgnorePrintAreas:=False, _
                             OpenAfterPublish:=False
        .Close savechanges:=False
End With
End Sub

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0

Gruß, René

[Rabe]

Hi Günter,

Ich habe den gesamten Vorgang einmal mit dem Makrorekorder aufgezeichnet - das könntest du auch machen und zum Verbessern und Verallgemeinern hier einstellen.

hier mal Dein Makro um Redundantes gekürzt:

Code:

Sub TestZweiTabAlsPDF()
'
' TestZweiTabAlsPDF Makro
'

'
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        "D:\01-Meine Daten\Forum\Testmappen\erstellte Testmappen\TestPDF.pdf", Quality _
        :=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
        OpenAfterPublish:=True
End Sub

[HajoHH]

Danke Mumpel .......die Idee mit kopieren und dann speichern war wohl die einfachste und beste ..... man sieht den Wald vor lauter bäumen nicht