externe Excel-Liste in "eigenes Format" bringen ??

[haserclaudia]

Hallo allerseits,   :21:
 
ich werde in der Arbeit derzeit von Extern mit (Excel-)Listen überhäuft, die mit unserem System nicht kompatibel sind. Ich muss die Listen nun alle selbständig in die „von uns benötigte“ Form (= auch Excel) bringen.
 
Nun bin ich leider was geht Excel angeht, ziemlich unbeholfen. Deshalb meine Frage/Bitte hier im Forum, ob jemand eine Idee hat, den Prozess zu automatisieren?? Also aus der Ursprungsliste die Blanko-Liste automatisiert zu befüllen.


 
Zur Erklärung: Ich kriege die Excel-Liste bestückt mit :
Listen-Nr.
Vorname,
Nachname,
Geburtsdatum,
Herkunft (in der Form:  italienisch)
Geschlecht (entweder steht in dieser Spalte Mutter, Tochter, Vater, etc. ODER ABER AUCH ein w für weiblich oder m für männlich),



Und ich muss Sie in eine Blanko Excel-Liste einfügen, die mit folgenden Spalten vorbelegt ist:
Nr.
Nachname
Geb.Datum
Vorname
Altersgruppe     (hier gibt es drei Unterscheidungen;  Kind =<14,    Erw. = >20 und die Unterscheidung  14-21)
Geschlecht         (hier darf nur ein w oder ein m  für weiblich oder männlich stehen)
Herkunftsland  (muss in der form Land: also Italien  stehen) 

Habe mal zur Veranschaulichung zwei Listen angehängt (nur Beispiele mit erfundenen Werten)
Liste 1= Ursprungsliste von Extern
Liste 2= Blanko-Liste wie sie dann aussehen soll.

Vielleicht kann mir ja jemand helfen!? 

Tausend Dank schon mal,

LG
Claudi


  Liste 1_Ursprung.xlsx (Größe: 9,15 KB / Downloads: 7)


  Liste 2_Blanko.xlsx (Größe: 9,22 KB / Downloads: 7)

[shift-del]

Hallo Claudia

Arbeitsblatt mit dem Namen 'Tabelle1'

B

C

D

E

F

G

H

I

J

K

L

M

N

3

Nr.

Nachname

Geb.Datum

Vorname

Altersgruppe

Geschlecht

Herkunftsland

4

5

1

Huber

01.01.2000

Andrea

14-21

w

Deutschland

Zelle	Formel
D5	=INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!F$5:F$34;$B5)
F5	=INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!H$5:H$34;$B5)
H5	=INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!D$5:D$34;$B5)
J5	=VERWEIS(DATEDIF(F5;HEUTE();"y");{0;15;20};{"Kind";"14-21";"Erw."})
L5	=WENN(ZÄHLENWENN(Tabelle2!$A$1:$A$7;INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!L$5:L$34;$B5));"w";"m")
N5	=SVERWEIS(INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!J$5:J$34;$B5);Tabelle2!$C$1:$D$5;2;FALSCH)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D
1	Cousine		deutsch	Deutschland
2	Ehefrau		spanisch	Spanien
3	Mutter		italienisch	Italien
4	Nichte		englisch	England
5	Schwester		schwedisch	Schweden
6	Tochter
7	w

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[WillWissen]

Hi Claudia,

obwohl dir shift-del eine Lösung angeboten hat, will ich dir meinen Vorschlag, der mit ausblendbaren Hilfsspalten arbeitet, nicht vorenthalten.


  haserclaudia-Liste1_Ursprung.xlsx (Größe: 15,36 KB / Downloads: 2)

  haserclaudia-Liste2.xlsx (Größe: 23,57 KB / Downloads: 2)

[Castor]

Hallo, Claudia & Detlef (& Günter);

habe mir mal Shift-Dels Lösung angesehen (WillWissen hat in seiner Lösung störende Bezüge auf seine eigenen Verzeichnisse drin), die soweit OK ist, nur die Altersgruppen werden nicht richtig gebildet (der 1.Fehler tritt in Zeile 14 auf). Deshalb würde ich die erste in der Formel enthaltene Matrixkonstante ändern:
J5[:J34]:=VERWEIS(DATEDIF(F5;J$1;"y");{0;14;22};{"Kind";"14-21";"Erw."})

Du hast in deinem Wunschergebnis allerdings auch einen Fehler in Zeile 20. Mit 30 sollte man eigentlich erwachsen sein...
Außerdem würde ich zum Vergleich nicht die Funktion HEUTE() verwenden, denn die ist dynamisch, sondern einen festen Stichtag (hier in J1).

Die Formeln in Spalten L und N könnte man auch mit Matrixkonstanten bestücken (ich habe dafür Hilfsmittel, mit denen sie schnell erzeugt sind) oder bei Hilfstabellen bleiben. Alternativ könnte man alle Matrixkonstanten auch in benannte Formeln auslagern und in den Zellformeln dann nur deren Namen benutzen. Dadurch werden letztere übersichtlicher und kürzer und der Pflegeaufwand für diese fällt nur an einer Stelle an. Eine Hilfstabelle ist allerdings leichter zu handhaben. Auch kann ebenfalls ein Name auf diese verweisen:

L5[:L34]:=INDEX({"m"."w"};1+ISTZAHL(VERGLEICH(INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!L$5:L$34;$B5);{"Cousine"."Ehefrau"."Mutter"."Nichte"."Schwester"."Tochter"."w"."weibl."."weiblich"};0)))

N5[:N34]:=INDEX({"Deutschland"."Frankreich"."Großbritannien"."Italien"."Portugal"."Schweden"."Spanien"};VERGLEICH("*"&WECHSELN(WECHSELN(WECHSELN(WECHSELN(INDEX('[Liste 1_Ursprung.xlsx]Tabelle1'!J$5:J$34;$B5);"isch";"");"zös";"k");"engl";"brit");"ies";"al")&"*";{"Deutschland"."Frankreich"."Großbritannien"."Italien"."Portugal"."Schweden"."Spanien"};0))

Ich habe in den Vergleichslisten/Matrixkonstanten dieser beiden Formeln noch etwas ergänzt, denn es gibt auch Länder, bei denen der Rückschluss (wie ich ihn per Formel versucht habe) vom Adjektiv auf das Land schwieriger ist. Auch ist England nur die Bezeichnung eines Teils von Großbritannien (Vereinigtes Königreich von ... oder UK wäre ggf noch besser). Und dann gibt's auch noch die Sache mit den Umlauten wie in niederländisch und französisch (da ist's allerdings noch mehr, weshalb ich das in der Formel berücksichtigt habe)...

Gruß, Castor

[haserclaudia]

Wow,

das ging ja schnell hier! Ihr seid ja Wahnsinn!

Tausend Dank schon mal,

jetzt werd ich mal kucken ob ich es umgesetzt bekomme.

GLG
Claudi