Anzahl Tage im Jahr

[Zwergel]

Hi Edgar,

danke für den Hinweis, vielleicht schaun die ja mal bei MS auch über den Tellerrand und bauen sowas in Office 2020 ein.

[Peter]

Hallo,

naja, in XL2013 gibt es die neue Funktion TAGE(), die die Anzahl von Tagen zwischen zwei Datumsangaben zurückgibt. Das geht eigentlich in die Richtung:

https://support.office.com/de-at/article...07bff0b9df

[schauan]

Hallo Peter,

mit dem Jahrhundert-Problem hat wohl jeder irgendwann zu kämpfen 

Hier mal Jörg's Formel und TAGE() im Vergleich unter Excel 2013:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	1900	365	366
2	2000	365	366

Zelle	Formel
B1	=TAGE("31.12."&A1;"1.1."&A1)
C1	=365+ISTZAHL(("29-2-"&A1)*1)
B2	=TAGE("31.12."&A2;"1.1."&A2)
C2	=365+ISTZAHL(("29-2-"&A2)*1)

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[Peter]

Hallo,

in diesem speziellen Fall (ich vermute mal weit über 95% aller Berechnungen berührt das gar nicht) führt dann tatsächlich die von mir gepostete und wieder gelöschte Formel zum richtigen Ergebnis:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	1900	366	365
2	2000	366	366

Zelle	Formel
B1	=365+ISTZAHL(("29-2-"&A1)*1)
C1	=365+(REST(A1;4)=0)-(REST(A1;100)=0)+(REST(A1;400)=0)
B2	=365+ISTZAHL(("29-2-"&A2)*1)
C2	=365+(REST(A2;4)=0)-(REST(A2;100)=0)+(REST(A2;400)=0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Tja, wenn damals die Marketing-Experten von Microsoft nicht die Oberhand behalten hätten und unbedingt mit Lotus1-2-3-Kompatibilität punkten wollten müssten wir uns vielleicht heute nicht mit diesem 'Problem' rumschlagen. :19:

[BoskoBiati]

Hallo,


da der Fehler ja nur im Jahr 1900 auftritt, weil man dem 1.1.1900 den Wert 1 zugewiesen hat, wäre es auch machbar, nur für dieses eine Jahr 1 abzuziehen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	1900	366	365	366	366	365
2	2000	366	366	366	366	366
3	2001	365	365	365	365	365

Zelle	Formel
B1	=("1.1."&A1+1)-("1.1."&A1)
C1	=("1.1."&A1+1)-("1.1."&A1)-(A1=1900)
D1	=365+ISTZAHL(("29-2-"&A1)*1)
E1	=DATUM(A1+1;1;1)-DATUM(A1;1;1)
F1	=365+(REST(A1;4)=0)-(REST(A1;100)=0)+(REST(A1;400)=0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo Peter,

mit dem Jahrhundert-Problem hat wohl jeder irgendwann zu kämpfen 

Hier mal Jörg's Formel und TAGE() im Vergleich unter Excel 2013...

Hi André, ich hatte ja geschrieben, dass "meine" Variante nicht für 1900 funzt... ... aber das ist ja ein Phänomen, dass bekannt ist und mit Peter's Formel z.B. bereinigt werden kann. Aber diese Geschichte kann man doch in den meisten Fällen vernachlässigen..., oder..? Was bei 2000 unter XL2013 rauskommt... ... naja...

[schauan]

Hallo zusammen,

Bei der TAGE - Formel muss man noch anderes berücksichtigen - sonst rechnet die immer falsch.
Zum einen steht in der Erklärung, dass der Zeitraum zwischen den beiden Daten berechnet wird. 31.12. und 1.1. geht also nicht. Man muss 2x den 1.1. nehmen, einmal vom Folgejahr, und einmal vom zu berechnenden Jahr, dann klappt es.
Nun könnte man ja sagen - zwischen zwei Tagen wäre der 31.12. des Vorjahres und der 1.1. des Folgejahres. Hier kommt aber der zweite Punkt zum Tragen. Excel nimmt für die Tage 0:00 Uhr an. Entsprechend ist der 1.1. des Jahres ein voller Tag in der Rechnung.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	1900	365	366
2	2000	365	366
3	2100	364	365
4	2200	364	365
5	2300	364	365
6	2400	365	366

Zelle	Formel
B1	=TAGE("31.12."&A1;"1.1."&A1)
C1	=TAGE("1.1."&A1+1;"1.1."&A1)
B2	=TAGE("31.12."&A2;"1.1."&A2)
C2	=TAGE("1.1."&A2+1;"1.1."&A2)
B3	=TAGE("31.12."&A3;"1.1."&A3)
C3	=TAGE("1.1."&A3+1;"1.1."&A3)
B4	=TAGE("31.12."&A4;"1.1."&A4)
C4	=TAGE("1.1."&A4+1;"1.1."&A4)
B5	=TAGE("31.12."&A5;"1.1."&A5)
C5	=TAGE("1.1."&A5+1;"1.1."&A5)
B6	=TAGE("31.12."&A6;"1.1."&A6)
C6	=TAGE("1.1."&A6+1;"1.1."&A6)

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg