Das Clever-Excel-Forum.de - Treffen
findet vom 15. - 17. September 2017 in Friedrichroda /
Thüringen / Region Großer Inselsberg statt. Hotelbuchung ab sofort möglich.

Aus Listbox ausgewählte Tabellen in einzelne PDF speichern
#1
Hallo,
ich habe eine vorhandenen Code aus diesen Forum umstricken in eine Listbox.
Wie bekomme ich das hin das aus der Listbox ausgewählte Tabellen in eine PDF-Datei in einem Verzeichnis speichere.
Der Name der PDF-Datei soll er aus der Tabelle2 A1 Und das Datum aus B1 entnehmen.
Danke für eure Hilfe.

Code:
Private Sub CommandButton1_Click()
   Dim i As Integer
   Dim vntSheetArray()      As Variant
   Dim intSheetCounter      As Long
   Dim bolOpenAfterPublish  As Boolean
   Dim contUFCheckboxes     As Control
   
   If MsgBox("Soll die Datei nach dem Erstellen angezeigt werden?", vbYesNo + vbQuestion, "Frage") = vbYes Then bolOpenAfterPublish = True

   For i = 0 To ListBox1.ListCount - 1
       If ListBox1.Selected(i) = True Then
       
       ReDim Preserve vntSheetArray(0 To ListBox1.ListCount)
         vntSheetArray(i) = ListBox1.ListCount
         ListBox1.Selected(i) = ListBox1.Selected(i) + 1
       
       ActiveWorkbook.Sheets(1).Copy
       
           Worksheets("Tabelle2").ExportAsFixedFormat xlTypePDF, Filename:= _
           "C:\Users\master\Documents\Messungen" & Worksheets("Tabelle2").Range("A1").Value & "_" & Format(Range("B1").Value, "dd.mm.yyyy") & ".pdf", _
           Quality:=xlQualityStandard, _
          IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True

       End If
   Next i
   
   bolOpenAfterPublish = False
   
   Unload Me
End Sub
to top
#2
Hallo,

Code:
Private Sub CommandButton1_Click()
 Dim i As Long, j As Long
 Dim vntSheetArray()      As Variant
 Dim bolOpenAfterPublish  As Boolean
 Dim oWsT2 As Worksheet

 With ListBox1
   For i = 0 To .ListCount - 1
     If .Selected(i) = True Then
       j = j + 1
       ReDim Preserve vntSheetArray(0 To j - 1)
       vntSheetArray(j - 1) = .List(i)
     End If
   Next i
 End With
 
 If j > 0 Then
   bolOpenAfterPublish = MsgBox("Soll die Datei nach dem Erstellen angezeigt werden?", vbYesNo + vbQuestion, "Frage") = vbYes
   Set oWsT2 = ActiveWorkbook.Worksheets("Tabelle2")
   ActiveWorkbook.Sheets(vntSheetArray).Copy
   With ActiveWorkbook
     .ExportAsFixedFormat Type:=xlTypePDF, _
                          Filename:="C:\Users\master\Documents\Messungen" & oWsT2.Range("A1").Value & "_" & Format(oWsT2.Range("B1").Value, "dd.mm.yyyy") & ".pdf", _
                          Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                          IgnorePrintAreas:=False, OpenAfterPublish:=bolOpenAfterPublish
     .Close SaveChanges:=False
   End With
 End If
 
 bolOpenAfterPublish = False
 Unload Me
End Sub

Gruß Uwe
to top
#3
Hallo,
super, vielen Dank!!
Gruß Andy 18
to top


Möglicherweise verwandte Themen...
Thema Verfasser Antworten Ansichten Letzter Beitrag
  Workbook speichern(aber nicht alle Tabellen) o0Julia0o 4 52 Vor 2 Stunden
Letzter Beitrag: mumpel
  Listbox erste Zeile michel34497 2 79 24.02.2017, 07:52
Letzter Beitrag: schauan
  einzelne Formeln ausschalten? T081A5 4 174 10.02.2017, 22:41
Letzter Beitrag: schauan
  Excel Abfrage - Wie können einzelne Spalten auf einem Blatt dargestellt werden?? excelblower 5 259 30.01.2017, 17:29
Letzter Beitrag: schauan
  listbox dynamisch erweitern Windlaeufer 7 265 29.01.2017, 11:54
Letzter Beitrag: snb
  Einzelne Texte in neue liste filtern planetlove 2 129 22.01.2017, 10:53
Letzter Beitrag: Peter
  Ausgewählte Zeilen verschiedener Tabellen in einer Tabelle zusammenfassen Chris482 7 381 14.01.2017, 15:11
Letzter Beitrag: Rabe
  Listbox Dbl Click Komentar einfügen michel34497 10 427 03.01.2017, 15:15
Letzter Beitrag: schauan
  Excel Tabellen mit VBA Code in PDF speichern Sykora 1 158 05.12.2016, 14:44
Letzter Beitrag: snb
  Listbox scrollen per VBA-Code Usedom 2 238 30.11.2016, 14:08
Letzter Beitrag: Usedom

Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste