Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

Formel gleich bzw. ungleich
#1
Hallo zusammen ,
habe ein kleineres Problem.
Tabelle ist im Anhang.
folgendes solltein der Zelle s4 funktionieren:
  1. wenn in B4 "ft" steht soll "g4+2*h4*i4 gerechnet werden.
  2. wenn in B4 "ft" und in D4 "x" steht soll folgendes gerechnet werden "2*h4*i4"
  3. wenn in B4 kein "ft" steht soll die die Zelle S4 leer sein 
habe schon angefangen die Formel zu basteln, bei Punkt 3 bin Ich gescheitert


Angehängte Dateien
.xlsx   Apu.xlsx (Größe: 10,1 KB / Downloads: 5)
Antworten Top
#2
Hallo,

ungetestet (nur aufgrund deiner Beschreibung):

=WENN(UND(B4="ft";D4="x");2*H4*I4;WENN(B4="ft";G4+2*H4*I4;""))
Gruß
Peter
[-] Folgende(r) 1 Nutzer sagt Danke an Peter für diesen Beitrag:
  • wavemaster
Antworten Top
#3
Hallo Peter,

habe einwenig umgetsellt
habe Ft mit f verwechselt
,

=WENN(UND(B4="f";D4="x");2*H4*I4;WENN(B4="f";(2*H4+G4)*I4;""))

passt und funzt.

Danke
Antworten Top
#4
Hi,

probier's mal so

PHP-Code:
=WENN(B4<>"ft";"";WENN(UND(B4="ft";D4="x");2*H4*I4;WENN(B4="ft";G4+2*H4*I4;""))) 
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
[-] Folgende(r) 1 Nutzer sagt Danke an WillWissen für diesen Beitrag:
  • wavemaster
Antworten Top
#5
Hi Wills wissen,
funzt ebenfalls.
Antworten Top
#6
(05.03.2015, 20:56)wavemaster schrieb: Hi Wills wissen,
funzt ebenfalls.

Habe noch ein 2 Problemchen gefunden.
in der Zelle K4 steht eine Formel die sollte so auch bleiben, jedoch sollte noch folgendes eingesetzt werden.
wenn in Zelle B4"f" und in Zelle D4"x" dann 2*h4*14
ansonsten die bestehende Formel.
das ist doch komplizierter

in Zelle k4 müßte dann 8 stehen.

Huh Huh Huh Dodgy Dodgy Dodgy Dodgy


Angehängte Dateien
.xlsx   Apu.xlsx (Größe: 10,15 KB / Downloads: 4)
Antworten Top
#7
Hi,

PHP-Code:
=WENN(UND(B4="f";D4="x");2*H4*I4;WENN(B4="f";(H4*2+G4)*I4;WENN(B4="r";(G4*2)*I4;WENN(B4="ft";(G4*2)*I4;WENN(B4="fk";G4*3,14*I4;""))))) 

wo genau hattest du denn mit dem Anfügen der weiteren Bedingung Probleme?
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
[-] Folgende(r) 1 Nutzer sagt Danke an WillWissen für diesen Beitrag:
  • wavemaster
Antworten Top
#8
(05.03.2015, 21:35)WillWissen schrieb: Hi,


PHP-Code:
=WENN(UND(B4="f";D4="x");2*H4*I4;WENN(B4="f";(H4*2+G4)*I4;WENN(B4="r";(G4*2)*I4;WENN(B4="ft";(G4*2)*I4;WENN(B4="fk";G4*3,14*I4;""))))) 

wo genau hattest du denn mit dem Anfügen der weiteren Bedingung Probleme?

mit den Klammern und wo das und zu setzen ist.
Aber wieder etwas gelernt

Danke
Antworten Top
#9
Hallo zusammen,

1. doppelte Bedingungen:

Code:
G4*G4*0,785>=2,5
G4^G4*0,785<=2,5

gilt auch für G4*H4!

In E4 gibt es "s" nicht als Möglichkeit, aber in J4

Ich würde das so angehen:

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
 BCDEFGHIJKLMNOPQRST
2            0,3      
3KürzelF_BankRollladenBauteilBezeichnungLängeHöheAnzahlFassadenflächeEckwinkelSockelflächeVOB AbzugLaibungenGerüstFensterbankFensterbankhalterBrandriegelApuleisteTropfkante
4fxxFenster 422-11,216 164,8 814 88

ZelleFormel
E4=VERWEIS(B4;{"ab";"br";"e";"f";"fbk";"ft";"gl";"gr";"gs";"gs-";"kg";"r";"se";""};{"Abzug";"Brandriegel";"Ecke";"Fenster";"Fenster(Kreis)";"Fensterbank";"Front";"Giebel links";"Giebel rechts";"Giebelspitze";"Giebelspitze";"Kein Gerüst";"Rückfront";"Sockel Erdreich";""})
J4=WENN((B4="")+(B4="fk")*(G4^2*0,785<=2,5)+(B4="f")*(G4*H4<=2,5)+(B4="se");"";WENN((B4="fk")*(G4^2*0,785>=2,5);-G4^2*0,785*I4+N4;WENN((B4="f")*(G4*H4>=2,5);-G4*H4*I4+N4;WENN(ODER(B4={"ab";"br";"s"});-G4*H4*I4;WENN(LINKS(B4;2)="gs";G4*H4*I4/2*(1-(B4="gs"-2)*2);G4*H4*I4)))))
K4=WENN(B4="f";(H4*2+G4)*I4;WENN(ODER(B4={"fk";"ft";"r"});G4*(2+(B4="fk")*1,4)*I4;""))
L4=WENN(ODER(B4={"s";"se"});G4*H4*I4;"")
M4=WENN((B4="f")*(G4*H4>=2,5);G4*H4*I4;WENN((B4="fk")*(G4^2*0,785>=2,5);G4^2*0,785*I4;""))
N4=WENN((B4="f")*(G4*H4>=2,5);(2*H4+G4)*I4*N2;WENN((B4="fk")*(G4^2/4*3,14>=2,5);G4*3,14*I4*N2;""))
O4=WENN(ODER(B4="kg";B4="ab";B4="f";B4="br";B4="s";B4="");"";WENN(#BEZUG!="";"";#BEZUG!))
P4=WENN(UND(B4="f";C4="x");G4*I4;"")
Q4=WENN(B4="f";WENN(C4="x";(RUNDEN((G4-0,4)/0,6;0)+1)*I4;0);"")
R4=WENN(B4="br";G4*H4*I4;"")
S4=WENN(B4="f";(2*H4+(D4<>"x")*G4)*I4;"")
T4=WENN(B4="f";G4*I4;"")
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste