Das Clever-Excel-Forum.de - Treffen
findet vom 15. - 17. September 2017 in Thüringen / Region Großer Inselsberg statt. Hotelbuchung ab sofort möglich.


Daten automatisch in ein anderes Tabellenblatt schreiben
#1
Hallo,
ist es möglich in einer Arbeitsmappe mit 9 Blättern das alle eingegebenen Daten automatisch in ein 10es Blatt übernommen werden.
Und zwar der Reihe nach von 1-9, also erst alle Daten von Blatt 1, dann Blatt 2 usw.
Wenn in einem Blatt Daten geändert werden sollen die sich in Blatt 10 natürlich auch ändern.
Die Tabellen beginnen bei A3 - I3 Blatt 1 - 9

Auf Blatt 10 sollen sie in B5 - J5 eingetragen werden mit einem Kürzel in A5 aus welchem Blatt die Daten kommen

Wenn dies nicht gehen sollte würde ich mich über ein kurzes das geht nicht genauso freuen wie über eine Lösung

Gruß
Thomas



.xlsm   Einteilung.xlsm (Größe: 78,64 KB / Downloads: 10)
to top
#2
Hallo Thomas,

kopiere den Code in das schon vorhandene VBA-Modul der Gesamttabelle:

Code:
Private Sub Worksheet_Activate()
  Dim i As Long
  Dim varQ As Variant
  Me.Range(Me.Cells(5, 1), Me.Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(, 10)) = ""
  For i = 1 To 9
    With Worksheets(i)
      If Len(.Cells(3, 1)) Then
        varQ = .Range(.Cells(3, 1), .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 9).Value
      Else
        ReDim varQ(0)
      End If
    End With
    If UBound(varQ) Then
      With Me.Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(UBound(varQ))
        .Value = Worksheets(i).Name
        .Offset(, 1).Resize(, UBound(varQ, 2)).Value = varQ
      End With
    End If
  Next i
End Sub

Gruß Uwe
to top
#3
Hallo Uwe,
vielen Dank dafür.
Es funktioniert aber nur teilweise, d.h. es werden nur die Daten der ersten drei Blätter übernommen.
Und weiter läuft mein Makro zum Speichern nicht mehr.
Ohne dein Makro laufen alle Makros ohne Probleme, wenn ich deines in dem Blatt eingefügt habe kommt beim Speichern ( strg+y) die Meldung Laufzeitfehler '9' Index ausserhalb des gültigen Bereichs.

Ich hänge die Originaltabelle mit allen Makros mal mit an, da ich den Fehler sowieso nicht finden werde.

Gruß
Thomas



.xlsm   Einteilung 2.xlsm (Größe: 141,04 KB / Downloads: 7)
to top
#4
Hallo Thomas,

das Makro funktioniert, also es holt Daten aus den Blättern,
wenn die jeweilige Zelle A3 nicht leer ist. Du solltest die Blätter
4 bis 9 daraufhin noch einmal überprüfen!

Wegen des Fehlers:
Lösche das Makro im Modul der Tabelle "Einteilung alle Ligen"
und füge in das Modul "DieseArbeitsmappe" folgenden Code ein:

Code:
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
  Dim i As Long
  Dim varQ As Variant
  If Sh.Name = "Einteilung alle Ligen" Then
    Sh.Range(Sh.Cells(5, 1), Sh.Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(, 10)) = ""
    For i = 1 To 9
      With Worksheets(i)
        If Len(.Cells(3, 1)) Then
          varQ = .Range(.Cells(3, 1), .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 9).Value
        Else
          ReDim varQ(0)
        End If
      End With
      If UBound(varQ) Then
        With Sh.Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(UBound(varQ))
          .Value = Worksheets(i).Name
          .Offset(, 1).Resize(, UBound(varQ, 2)).Value = varQ
        End With
      End If
    Next i
  End If
End Sub

Gruß Uwe
[-] Folgende(r) 1 Benutzer sagt Danke an Kuwer für diesen Beitrag:
knallebumm
to top
#5
Hallo Uwe,
vielen Dank es rockt.
Man sollte schon aufpassen wenn man das Blatt öffnet in welcher Zeile sich die Maus befindet29.
Mit dem Speichern klappt jetzt auch.

Gruß
Thomas
to top


Möglicherweise verwandte Themen...
Thema Verfasser Antworten Ansichten Letzter Beitrag
  Filtern Liste und Daten auf anderes Sheet kopieren Rabe 8 117 06.12.2016, 15:49
Letzter Beitrag: Rabe
  Daten automatisch in neue Zelle redburningice 1 115 25.11.2016, 22:39
Letzter Beitrag: schauan
  (berechnete) Teilbereiche in anderes Blatt kopieren Timo 12 232 23.11.2016, 16:29
Letzter Beitrag: Gast 123
  Formel kürzer schreiben coemm 5 95 13.11.2016, 19:47
Letzter Beitrag: BoskoBiati
  VB Daten in anderes Tabellenblatt übertragen derhanfti 3 103 07.11.2016, 07:56
Letzter Beitrag: derhanfti
  Daten nach Entscheidung in anderes Blatt schreiben appelschnut 5 99 27.10.2016, 17:03
Letzter Beitrag: appelschnut
  VBA: In berechnete Zielzelle schreiben hellidor 3 127 02.10.2016, 07:49
Letzter Beitrag: hellidor
  Mehrere Schriftformate einer Zelle mit Bezug in anderes Tabellenblatt Ingo49 10 371 25.09.2016, 09:50
Letzter Beitrag: Ingo49
  VBA - Inhalte in bestimmte Zellen schreiben Wiiinnniii 12 550 18.08.2016, 10:59
Letzter Beitrag: IchBinIch
Smile Zeilen in ein anderes Tabellenblatt kopieren sindy231 3 338 08.08.2016, 14:42
Letzter Beitrag: Rabe

Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste