Hallo zusammen,
ich hab ein Problem bei meiner Formel "Sverweis" und zwar funktioniert meine Formel, wenn ich über 3 Tabellen suche, sobald ich über 4 Tabellen suche will, meckert Excel "zuviel Argumente".
Hier die Formel:
Code:
=Wenn(Istfehler(SVERWEIS($A$3;Tabelle2!$B40:$H69;2;0));SVERWEIS($A$3;Tabelle3!B40:H89;2;0);SVERWEIS($A$3;Tabelle4!$B40:$H89;2;0);SVERWEIS($A$3;Tabelle5!$B40:$H69;2;0))
Wo ist mein Fehler?
hi Bernie, kannst du mal bitte (D)eine (Beispiel)Datei posten..?
Hallo Jockel,
hier meine Datei: [URL=
Dateiupload bitte im Forum! So geht es: Klick mich!]
Sverweis ist auf Tabelle 6
Danke schon mal im Voraus für deine Hilfe.
Hallo Bernie, Du kannst hier Deine Datei(en) direkt hochladen...
Hallo Bernie, meinst du so..?
Als Fehlerabfrage einfach WENNFEHLER() umzu tun...
Arbeitsblatt mit dem Namen 'Limitüberwachung' |
| A | B | C | D | E |
1 | Portfolio | | | | |
2 | Name | Kaufkurs | akt. Kurs | GuV % | Order |
3 | Fielmann | 56,00 | 50,08 | -10,56 | verkaufen |
4 | Continental | 140,00 | 166,80 | 19,14 | halten |
Zelle | Formel |
C3 | =SVERWEIS($A3;INDIREKT("'"&INDEX({"DAX";"MDAX";"SDAX";"TECDAX"};VERGLEICH(1;(ZÄHLENWENN(INDIREKT("'"&{"DAX";"MDAX";"SDAX";"TECDAX"}&"'!B:B");$A3)>0)+0;0))&"'!$B40:H69");2;0) |
D3 | =WENN(A3="";"";(C3-B3)/B3%) |
E3 | =WENN(A3="";"";WENN(D3<-9,99;"verkaufen";"halten")) |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo Jockel,
passt wie Faust auf's Auge, Danke sehr!!!
Kurze Frage noch "wie kann ich Dateien direkt hochladen, hab gesucht im Forum, aber nichts gefunden.
Hallo,
ginge ohne größeren Aufwand auch so:
Code:
=WENNFEHLER(SVERWEIS($A$3;Tabelle2!$B40:$C69;2;0);WENNFEHLER(SVERWEIS($A$3;Tabelle3!B40:C89;2;0);WENNFEHLER(SVERWEIS($A$3;Tabelle4!$B40:$C89;2;0);WENNFEHLER(SVERWEIS($A$3;Tabelle5!$B40:$C69;2;0);"nicht da"))))
Hallo
Hier noch zwei Varianten von mir.
| A | B | C | D | E | F | G | H | I | J | K | L | M |
2 | Name | Kaufkurs | akt. Kurs | GuV % | Order | | | | | | | | |
3 | Fielmann | 56,00 | 50,08 | -10,56 | verkaufen | | #NV | 50,084 | #NV | #NV | 50,084 | | 50,084 |
4 | Continental | 140,00 | #NV | #NV | #NV | | 166,8 | #NV | #NV | #NV | 166,8 | | 166,8 |
Zelle | Formel |
G3 | =SVERWEIS(A3;DAX!$B$40:$C$100;2;FALSCH) |
H3 | =SVERWEIS(A3;MDAX!$B$40:$C$100;2;FALSCH) |
I3 | =SVERWEIS(A3;SDAX!$B$40:$C$100;2;FALSCH) |
J3 | =SVERWEIS(A3;TECDAX!$B$40:$C$100;2;FALSCH) |
K3 | =VERWEIS(9^9;G3:J3) |
M3 | =SVERWEIS(A3;INDIREKT(VERWEIS(42;1/ZÄHLENWENN(INDIREKT({"DAX"."MDAX"."SDAX"."TECDAX"}&"!B:B");A3);{"DAX"."MDAX"."SDAX"."TECDAX"})&"!B40:C100");2;FALSCH) |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Die zweite Variante ist eine Abwandlung von Jörgs Formel.
Ein Geschwindigkeitsvergleich auf Basis der Hilfsspalten-Lösung zeigt:
Hilfsspalten | INDIREKT() | Verschachtelt |
1 | 1,6 | 2,2 |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |