Hallo zusammen ,
habe ein kleineres Problem.
Tabelle ist im Anhang.
folgendes solltein der Zelle s4 funktionieren:
- wenn in B4 "ft" steht soll "g4+2*h4*i4 gerechnet werden.
- wenn in B4 "ft" und in D4 "x" steht soll folgendes gerechnet werden "2*h4*i4"
- wenn in B4 kein "ft" steht soll die die Zelle S4 leer sein
habe schon angefangen die Formel zu basteln, bei Punkt 3 bin Ich gescheitert
Hallo,
ungetestet (nur aufgrund deiner Beschreibung):
=WENN(UND(B4="ft";D4="x");2*H4*I4;WENN(B4="ft";G4+2*H4*I4;""))
Hallo Peter,
habe einwenig umgetsellt
habe Ft mit f verwechselt
,
=WENN(UND(B4="f";D4="x");2*H4*I4;WENN(B4="f";(2*H4+G4)*I4;""))
passt und funzt.
Danke
Hi Wills wissen,
funzt ebenfalls.
(05.03.2015, 20:56)wavemaster schrieb: [ -> ]Hi Wills wissen,
funzt ebenfalls.
Habe noch ein 2 Problemchen gefunden.
in der Zelle K4 steht eine Formel die sollte so auch bleiben, jedoch sollte noch folgendes eingesetzt werden.
wenn in Zelle B4"f" und in Zelle D4"x" dann 2*h4*14
ansonsten die bestehende Formel.
das ist doch komplizierter
in Zelle k4 müßte dann 8 stehen.
Hi,
PHP-Code:
=WENN(UND(B4="f";D4="x");2*H4*I4;WENN(B4="f";(H4*2+G4)*I4;WENN(B4="r";(G4*2)*I4;WENN(B4="ft";(G4*2)*I4;WENN(B4="fk";G4*3,14*I4;"")))))
wo genau hattest du denn mit dem Anfügen der weiteren Bedingung Probleme?
(05.03.2015, 21:35)WillWissen schrieb: [ -> ]Hi,
PHP-Code:
=WENN(UND(B4="f";D4="x");2*H4*I4;WENN(B4="f";(H4*2+G4)*I4;WENN(B4="r";(G4*2)*I4;WENN(B4="ft";(G4*2)*I4;WENN(B4="fk";G4*3,14*I4;"")))))
wo genau hattest du denn mit dem Anfügen der weiteren Bedingung Probleme?
mit den Klammern und wo das und zu setzen ist.
Aber wieder etwas gelernt
Danke
Hallo zusammen,
1. doppelte Bedingungen:
Code:
G4*G4*0,785>=2,5
G4^G4*0,785<=2,5
gilt auch für G4*H4!
In E4 gibt es "s" nicht als Möglichkeit, aber in J4
Ich würde das so angehen:
Arbeitsblatt mit dem Namen 'Tabelle1 (2)' |
| B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T |
2 | | | | | | | | | | | | | 0,3 | | | | | | |
3 | Kürzel | F_Bank | Rollladen | Bauteil | Bezeichnung | Länge | Höhe | Anzahl | Fassadenfläche | Eckwinkel | Sockelfläche | VOB Abzug | Laibungen | Gerüst | Fensterbank | Fensterbankhalter | Brandriegel | Apuleiste | Tropfkante |
4 | f | x | x | Fenster | | 4 | 2 | 2 | -11,2 | 16 | | 16 | 4,8 | | 8 | 14 | | 8 | 8 |
Zelle | Formel |
E4 | =VERWEIS(B4;{"ab";"br";"e";"f";"fbk";"ft";"gl";"gr";"gs";"gs-";"kg";"r";"se";""};{"Abzug";"Brandriegel";"Ecke";"Fenster";"Fenster(Kreis)";"Fensterbank";"Front";"Giebel links";"Giebel rechts";"Giebelspitze";"Giebelspitze";"Kein Gerüst";"Rückfront";"Sockel Erdreich";""}) |
J4 | =WENN((B4="")+(B4="fk")*(G4^2*0,785<=2,5)+(B4="f")*(G4*H4<=2,5)+(B4="se");"";WENN((B4="fk")*(G4^2*0,785>=2,5);-G4^2*0,785*I4+N4;WENN((B4="f")*(G4*H4>=2,5);-G4*H4*I4+N4;WENN(ODER(B4={"ab";"br";"s"});-G4*H4*I4;WENN(LINKS(B4;2)="gs";G4*H4*I4/2*(1-(B4="gs"-2)*2);G4*H4*I4))))) |
K4 | =WENN(B4="f";(H4*2+G4)*I4;WENN(ODER(B4={"fk";"ft";"r"});G4*(2+(B4="fk")*1,4)*I4;"")) |
L4 | =WENN(ODER(B4={"s";"se"});G4*H4*I4;"") |
M4 | =WENN((B4="f")*(G4*H4>=2,5);G4*H4*I4;WENN((B4="fk")*(G4^2*0,785>=2,5);G4^2*0,785*I4;"")) |
N4 | =WENN((B4="f")*(G4*H4>=2,5);(2*H4+G4)*I4*N2;WENN((B4="fk")*(G4^2/4*3,14>=2,5);G4*3,14*I4*N2;"")) |
O4 | =WENN(ODER(B4="kg";B4="ab";B4="f";B4="br";B4="s";B4="");"";WENN(#BEZUG!="";"";#BEZUG!)) |
P4 | =WENN(UND(B4="f";C4="x");G4*I4;"") |
Q4 | =WENN(B4="f";WENN(C4="x";(RUNDEN((G4-0,4)/0,6;0)+1)*I4;0);"") |
R4 | =WENN(B4="br";G4*H4*I4;"") |
S4 | =WENN(B4="f";(2*H4+(D4<>"x")*G4)*I4;"") |
T4 | =WENN(B4="f";G4*I4;"") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |