Hallo Forum,
ich habe eine Zweispaltige Vorlage, in deren erster Spalte ein Begriff und in der zweiten Spalte eine zugehörige Übersetzung steht.
Bsp.:
nose Nase
house Haus
wired seltsam
Nun will ich eine neue Liste mit z.B. englischen Wörtern, die ebenfalls Spaltenweise aufgelistet sind mit obiger ersten Liste vergleichen und im Falle von schon bekannter Übersetzung aus der ersten Liste diese in die nächste Spalte ausgeben.
Bsp:
tent
house Haus
glass
nose Nase
könnt ihr mir helfen, hier eine Vergleichsformel aufzusetzen?
vielen Dank!
Hallo
Eine Aufgabe für
SVERWEIS().
SVERWEIS() hat vier Parameter.
Falls die erste Spalte nicht aufsteigend sortiert ist, muß der vierte Parameter zwingend FALSCH sein.
Hi,
das sollte es treffen:
| Arbeitsblatt mit dem Namen 'Liste1' |
| | A | B |
| 1 | Englisch | Deutsch |
| 2 | house | Haus |
| 3 | nose | Nase |
| 4 | wired | seltsam |
| Arbeitsblatt mit dem Namen 'Liste2' |
| | A | B |
| 1 | Englisch | Deutsch |
| 2 | tent | |
| 3 | house | Haus |
| 4 | glass | |
| 5 | nose | Nase |
| Zelle | Formel |
| B2 | =WENNFEHLER(SVERWEIS($A2;Liste1!$A$1:$B$4;2;FALSCH);"") |
| B3 | =WENNFEHLER(SVERWEIS($A3;Liste1!$A$1:$B$4;2;FALSCH);"") |
| B4 | =WENNFEHLER(SVERWEIS($A4;Liste1!$A$1:$B$4;2;FALSCH);"") |
| B5 | =WENNFEHLER(SVERWEIS($A5;Liste1!$A$1:$B$4;2;FALSCH);"") |
Gruß
Max
Edit sagt:
Wenn Du Deinen Referenzbereich als Tabelle formatierst, brauchst Du nicht jedes Mal
Deine Matrix im Sverweis-Teil anzupassen wenn Du eine Vokabel ergänzt, da sich dieser automatisch mit anpasst.
Hier mal beide Listen in einer Tabelle.
| Arbeitsblatt mit dem Namen 'Liste1' |
| | A | B | C | D | E |
| 1 | Englisch | Deutsch | | Englisch | Deutsch |
| 2 | house | Haus | | tent | |
| 3 | nose | Nase | | house | Haus |
| 4 | wired | seltsam | | glass | |
| 5 | disappointed | enttäuscht | | nose | Nase |
| 6 | exhausted | erschöpft | | exhausted | erschöpft |
| Zelle | Formel |
| E2 | =WENNFEHLER(SVERWEIS($D2;Referenz;2;FALSCH);"") |
| E3 | =WENNFEHLER(SVERWEIS($D3;Referenz;2;FALSCH);"") |
| E4 | =WENNFEHLER(SVERWEIS($D4;Referenz;2;FALSCH);"") |
| E5 | =WENNFEHLER(SVERWEIS($D5;Referenz;2;FALSCH);"") |
| E6 | =WENNFEHLER(SVERWEIS($D6;Referenz;2;FALSCH);"") |
Hallo Max,
danke für die Hilfe, aktuell klappt das bei mir nicht, ich benutze Excel 2000, evtl. liegt's daran.
ich bekomme eine #name? Fehlermeldung.
Grüße,
Stefan
Hallo Stefan,
hast Du die Formel kopiert oder abgetippt?
#NAME lässt
a) auf einen Tippfehler oder
b) auf einen falsch definierten Bereich schließen
Kannst Du eine Beispieldatei mit ein paar Referenzen einstellen?
Gruß
Max
Edit sagt:
Hier steht wie es geht.
Hi,
das mit der formatierten Tabelle funktioniert unter Excel 2000 nicht.
Sorry zu spät gesehen.
Schau mal hier:
[
attachment=1479]
Gruß
Max
Hallo Max,
WENNFEHLER() gibt es ab 2007, daher der Fehler #Name?
(12.02.2015, 23:04)atilla schrieb: [ -> ]Hallo Max,
WENNFEHLER() gibt es ab 2007, daher der Fehler #Name?
Stimmt. Das hatte ich nicht auf dem Schirm.
Danke.
Gruß
Max
Hi Stefan.
bei Dir sollte das dann so funktionieren:
Formel für B2 in Tabelle2:
Code:
=WENN(ISTFEHLER(SVERWEIS($A2;Liste2!$A$2:$B$6;2;FALSCH));"";SVERWEIS($A2;Liste2!$A$2:$B$6;2;FALSCH))
sonst, wenn beide Bereiche in einer Tabelle liegen wie im Edit von Post#3
Code:
=WENN(ISTFEHLER(SVERWEIS($D2;$A$2:$B$6;2;FALSCH));"";SVERWEIS($D2;$A$2:$B$6;2;FALSCH))
Die Formelprofis hier haben vielleicht noch andere Lösungen.
Sorry und Gruß
Max
Hallöchen,
ich nehme bei der "Vorbereitung" meist Zählenwenn und nicht Istfehler.
Code:
=WENN(ZÄHLENWENN($A2;Liste2!$A$2:$B$6);SVERWEIS($A2;Liste2!$A$2:$B$6;2;FALSCH);"")