wenn + und

[Ronbom10]

nein, ich erwarte hier nichts mehr.  werde meine Account löschen.
Habe höflich nach einer Lösung gefragt, aber Eure Antworten sind alle nicht wirklich "CLEVER"

Vielen Dank für nichts und eine schöne Woche

[Ronbom10]

ach ja,  ich hab die Lösung für meinen Ausgangspost:

Code:

=WENN(UND(A1>0;A1>A2);"2";WENN(UND(A1>0;A1<A2);"1";WENN(UND(A1<0;A1>A2);"-1";WENN(UND(A1<0;A1<A2);"-2"))))

war gar nicht so schwer ihr Helden :D

[M.Wichmann]

Hallo,

ich will ja nix sagen. Aber die Formeln machen alle das selbe.
Habe das gerade mal probiert. Die Formeln die in deinen Augen nicht funktionieren können machen genau das selbe. 
Nur deutlich einfacher aufgebaut. Sicherlich sieht die gegenüber deiner Wennformel sehr "mikrig" aus, aber fakt ist, sie funktionieren.

[Ronbom10]

Du hast Recht, es funktionieren beide Formeln !

Da hab ich mich wohl ziemlich in die Nesseln gesetzt.  Hätte ich nie im Leben gedacht, das die einfache Formel funktioniert. 
Ich habe Sie leider nicht ausprobiert, da meine Werte A1 und A2 in einem anderen Register liegen.

Dann bedanke ich mich herzlich bei @[b]BoskoBiati   und entschuldige mich bei den anderen für mein Unverständnis.[/b]

Schönen Tag Euch allen  :)

[BoskoBiati]

Hi,

zu allem Überfluß werden mit der komischen WENN-Formel Texte erzeugt und keine Zahlen. Eine sinnleere Aneinanderreihung von Wenn ist zudem keine vernünftige Formel. Wenn, dann wären die ersten drei noch akzeptabel:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D
1	4	4	-4	-4
2	5	3	-3	-5
3	1	2	-2	-1
4	1	2	-2	-1
5	1	2	-2	-1
6	1	2	-2	-1
7	1	2	-2	-1
8	1	2	-2	-1

Zelle	Formel
A3	=WENN(A1>0;WENN(A1>A2;2;1);WENN(A1>A2;-1;-2))
A4	=WENN(A1>A2;WENN(A1>0;2;-1);WENN(A1<=0;-2;1))
A5	=WENN(A1>A2;2;1)-WENN(A1<=0;3;0)
A6	=WENN(A1>A2;2;1)-(A1<=0)*3
A7	=2-(A1<A2)-(A1<0)*3
A8	=1+(A1>A2)-(A1<0)*3

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Ronbom10]

Erst einmal danke für das Beispiel.  So langsam verstehe ich es .  Ist ja genial   

ja, dass diese wenn Formeln ihre Ergebnisse als Text und nicht als Zahl ausgeben, musste ich gestern dann auch feststellen :(

Die Ergebnisse, die mir diese Forrmeln bringen, möchte ich dann noch farblich mit der bedingten Formatierung unterscheiden und dann auch noch zusammenrechnen.
habe erst einmal ziemlich gestutzt, als das mit der bedingten Formatierung nicht ging.  Musste dann den Textwert in "x" setzen, aber es ist nicht optimal.
Dank deiner Formel, ist es aber alle hübsch.

Hast du, oder jemand anderes eine Idee, wie ich folgende Bedingungen ohne wenn hin bekomme ?

• Werte größer 70 = 2
  
• Werte zwischen 30 und 70 = 0
  
• Werte kleiner 30 = -2
  

[LCohen]

=VERGLEICH(A1;{-999;30;70,01})*2-4
oder
=VORZEICHEN(KÜRZEN((A1-50)/21))*2
oder
=KÜRZEN(MEDIAN(-1;(A1-50)/20;1))*2

(mit unterschiedlichen Abgrenzungen!)

[Elex]

Hi

oder nach dir jetzt bekannteren Muster.

=(A1<30)*-2+(A1>70)*2

[Ronbom10]

komisch, aber irgendwie funktioniert das bei mir alles nicht.   

Werte zwischen 30 und 70 sollen 0 (Null) ergeben und bei Euren Formeln kommt entweder 2 oder -2 dabei heraus....

[steve1da]

Hola,

funktioniert wunderbar. Liegen die Zahlen evtl als Text vor? Prüf das mal mit =Istzahl(A1)

Gruß,
steve1da