spezielle Geburtstagsliste

[Al Swearengen]

Hallo!

Ich möchte, daß mir Excel ab Zelle J3 runtergehend alphabetisch meiner beigefügten Liste anzeigt, wer am heutigen Tag Geburtstag hat. Das sollte sich automatisch jeden Tag aktualisieren, wenn das Datum wechselt. Auch sollte mir das dazugehörige Alter in Jahren ab der Zelle K3 runtergehend angezeigt werden.

Ich habe insofern schon ein wenig vorgearbeitet, daß zumindest die Anzahl der "Geburtstagskinder" angezeigt wird. Vielleicht hat jemand dazu eine Idee?


  Geburtstagsliste.xlsx (Größe: 176,75 KB / Downloads: 14)

[{Boris}]

Hi,

schreibe in H3:

=WENN((TAG(F3)=TAG(HEUTE()))*(MONAT(F3)=MONAT(HEUTE()));ZEILE();"")

und kopier die Formel runter.

Jetzt in J3:

=WENNFEHLER(INDEX(B:B;KKLEINSTE($H:$H;ZEILEN($1:1)));"")

Nach rechts kopieren und auch so weit runter, wie maximal Leute am selben Tag Geburtstag haben können.

[Al Swearengen]

Vielen Dank, Boris!

Das ist genau das, was ich wollte.

Super!

[HKindler]

Hi,

nur um dir den Mund wässrig zu machen...

Bei aktuellem Excel reicht

=FILTER(B3:C789;(TAG(F3:F789)=TAG(HEUTE()))*(MONAT(F3:F789)=MONAT(HEUTE())))

um alle Namen samt Vornamen zu bekommen.

Wenn diese Formel in J3 steht, bekommst du die Anzahl der Geburtstagskinder dann mit

=ZEILEN(J3#)

[RPP63]

Moin und sabber!
Die Prüfung würde ich anders machen:
Statt 
(TAG(F3:F789)=TAG(HEUTE()))*(MONAT(F3:F789)=MONAT(HEUTE()))
nehme ich 
TEXT(HEUTE();"MMTT")=TEXT(F3:F789;"MMTT")

Außerdem zur Verhinderung von #KALK! bei keinem Treffer:
=FILTER(B3:C789;TEXT(HEUTE();"MMTT")=TEXT(F3:F789;"MMTT");"niemand")

Gruß Ralf

[ws-53]

Früher oder später kommmt normalerweise die Frage, dass wenn die Mappe wegen Wochenende oder Feiertage nicht geöffnet wurde, auch die somit versäumten Geburtstage angezeigt werden sollen.

Dafür eine mit Power Query erstellte Lösung die immer die Geburtstage ab dem Tag nach dem letzten öffnen zeigt. Sofern die Mappe "heute" bereits geöffnet wurde, werden auch die "heutigen" Geburtstage gezeigt.

Über das Tabellenblatt "Last_Open" kann über die Zelle B2 auch gesteuert werden, dass auch noch weiter zurückliegende Geburtstage gezeigt werden. Eine Änderung dieses Werts wirken ab dem nächten öffnen bzw. wenn die Geburtagsliste aktualisiert wird.