Zellenpaare Summieren

[moritz.vette]

Hallo zusammen,

ich hoffe Ihr könnt mir helfen, ich habe zu meiner Frage nämlich leider nichts finden können. Eine Excel-Datei habe ich angehängt um mein Problem zu verdeutlichen.

Ich habe eine Tabelle, die in 3 Spalten aufgebaut ist (A=Startpunkt, B=Endpunkt, C=Punkte). Ich möchte herausfinden wieviele Punkte auf jeder Route zwischen Start- und Endpunkt gesammelt werden. Allerdings soll die Route "A-B" gleichzeitig die Route "B-A" beinhalten (also die Punkte für beide Richtungen summiert werden). 

Als Ergebnis würde ich mir wünschen, dass ich sehe, wieviel Punkte auf jeder Route z.B. A-B (inkl. B-A) gesammelt werden.

Das Datenblatt welches ich verwende besteht aus mehreren Tausend Zeilen, weshalb ich die Harmonisierung der Routen nicht per Hand durchführen kann.

-------------------------

Bis jetzt habe ich probiert das ganze in einer Pivot Tabelle als Matrix darzustellen. In der Pivottabelle gibt es dann jeweils einen Eintrag für jedes Routenpaar. Wie kann ich diese jedoch zusammenfügen? (Die Index Funktion könnte als Basis dienen, aber dennoch muss ich es irgendwie schaffen, die Abhängigkeit der Routenpaare zu definieren und da komme ich nicht weiter...



Ich freue mich auf Hilfe von Euch:)


Viele Grüße

Moritz

[Elex]

Hi

Hilft dir das weiter.

____|_____A____|____B___|___C__|D|E|__F__|G|___H__|__I_|
   1|Startpunkt|Endpunkt|Punkte| | |Route| |Punkte|    |
   2|A         |C       |  1400| | |A    |B|  1626|1626|
   3|B         |A       |  1500| | |A    |C|  1747|1747|
   4|C         |B       |  1100| | |A    |D|   105| 105|
   5|D         |C       |  2123| | |B    |C|  1324|1324|
   6|A         |B       |   123| | |B    |D|   212| 212|
   7|B         |C       |   212| | |C    |D|  2273|2273|
   8|C         |A       |    24| | |     | |      |    |
   9|D         |A       |     5| | |     | |      |    |
  10|A         |B       |     3| | |     | |      |    |
  11|B         |C       |    12| | |     | |      |    |
  12|C         |A       |   323| | |     | |      |    |
  13|D         |B       |    12| | |     | |      |    |
  14|A         |D       |   100| | |     | |      |    |
  15|B         |D       |   200| | |     | |      |    |
  16|C         |D       |   150| | |     | |      |    |

H2    =SUMMEWENNS($C$2:$C$16;$A$2:$A$16;F2;$B$2:$B$16;G2)+SUMMEWENNS($C$2:$C$16;$A$2:$A$16;G2;$B$2:$B$16;F2)

I2    =SUMMENPRODUKT((($A$2:$A$16=F2)*($B$2:$B$16=G2)+($A$2:$A$16=G2)*($B$2:$B$16=F2))*$C$2:$C$16)

Zwei verschiedene Formel. Teste aus ob eine bei mehreren Tausend Zeilen evtuell schneller läuft.

[Jockel]

Hallo, ich denke das könnte man mit einer Datentabelle lösen..!?!

Arbeitsblatt mit dem Namen 'Blatt1'
	B	C	D	E	F	G	H	I	J	K
2	Startpunkt	Endpunkt	Punkte			Startpunkt	A
3	A	C	1400			Endpunkt	B
4	B	A	1500				1626
5	C	B	1100
6	D	C	2123				A	B	C	D
7	A	B	123			A		1626	1747	105
8	B	C	212			B	1626		1324	212
9	C	A	24			C	1747	1324		2273
10	D	A	5			D	105	212	2273
11	A	B	3
12	B	C	12
13	C	A	323
14	D	B	12
15	A	D	100
16	B	D	200
17	C	D	150

Zelle	Format	Wert
G6	;;;	1626
H7	Standard;;	0
I7	Standard;;	1626
J7	Standard;;	1747
K7	Standard;;	105
H8	Standard;;	1626
I8	Standard;;	0
J8	Standard;;	1324
K8	Standard;;	212
H9	Standard;;	1747
I9	Standard;;	1324
J9	Standard;;	0
K9	Standard;;	2273
H10	Standard;;	105
I10	Standard;;	212
J10	Standard;;	2273
K10	Standard;;	0

Zelle	Formel
H4	=SUMMENPRODUKT((($B$3:$B$17=H2)*($C$3:$C$17=H3)+($B$3:$B$17=H3)*($C$3:$C$17=H2))*$D$3:$D$17)
G6	=H4
H7	{=MEHRFACHOPERATION(H2;H3)}
I7	{=MEHRFACHOPERATION(H2;H3)}
J7	{=MEHRFACHOPERATION(H2;H3)}
K7	{=MEHRFACHOPERATION(H2;H3)}
H8	{=MEHRFACHOPERATION(H2;H3)}
I8	{=MEHRFACHOPERATION(H2;H3)}
J8	{=MEHRFACHOPERATION(H2;H3)}
K8	{=MEHRFACHOPERATION(H2;H3)}
H9	{=MEHRFACHOPERATION(H2;H3)}
I9	{=MEHRFACHOPERATION(H2;H3)}
J9	{=MEHRFACHOPERATION(H2;H3)}
K9	{=MEHRFACHOPERATION(H2;H3)}
H10	{=MEHRFACHOPERATION(H2;H3)}
I10	{=MEHRFACHOPERATION(H2;H3)}
J10	{=MEHRFACHOPERATION(H2;H3)}
K10	{=MEHRFACHOPERATION(H2;H3)}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[moritz.vette]

Es hat wunderbar mit der SUMMENPRODUKT Funktion geklappt:)

Vielen Dank