Zellen verketten

[schluckspecht]

Hallo Zusammen,
ich beschäftige mich gerade mit Verketten.
Gibt es eine einfachere Art die Wertezellen zu verketten.
Wenn's geht dynamisch.Und das die "Leerzellen" nicht mit Kommas eingebunden werden.
In Blatt 1+Blatt 2 sind je 1 Tabelle,die unterschiedlich aufgebaut sind.
Darauf hin wurde in Blatt 2 unter Variante 2 eine Aggregatformel angewendet.
Das Problem ist,die Werte werden aus der Tabelle von rechts nach links angezeigt.
Warum? Kann man dies ändern?
In Blatt 1 wurde die Aggregatformel erst garnicht angewendet.

Da ich wohl zusätzlich mit Zeilen arbeiten müsste.*Denkichmal*
Doch hier hapert's dann an die Formelzusammenstellung.


Danke

[neopa]

Hallo,

... Deine Frage zu Variante 2 ist einfach beantwortet. Wenn Du das 1. Argument der Funktion AGGREGAT() bei Dir die 14 abänderst zu einer 15 bekommst Du die richtige Reihenfolge.

Für das was Du anstrebst kann die Formel zunächst verkürzt und muss danach ergänzt werden, damit sie unter Einbeziehung von ausblendbaren Hilfsspalten rechts der Ergebnisspalte dort das angestrebte listet.

Folgende Formel in J2:

PHP-Code:

=WENNFEHLER(INDEX($A$1:$H$1&TEXT($A2:$H2;" 0%");AGGREGAT(15;6;SPALTE($B2:$H2)/($B2:$H2>0);SPALTE(A2)))&WENN(K2="";"";", "&K2);"") 


Diese Formel weit genug nach rechts ziehend kopieren und danach die Formeln nach unten.

Das angestrebte Ergebnis findest Du danach in J2:J## Die Hilfsspalten K: L einfach ausblenden.

[schluckspecht]

@neopa
Super,danke
Könnte man auch deine Formel umsetzten auf Blatt 1?

Danke

[neopa]

Guten Morgen,

ja, das geht auch.

Nachfolgend ein Lösungsvorschlag der zwar das Listing gemäß den Namen in G5:G8 vornimmt, jedoch ohne sich direkt auf diese Zellen zu beziehen.

in H5:

PHP-Code:

=WENNFEHLER(INDEX($A$1:$A$19&TEXT(INDEX($B$1:$E$19;;ZEILE(A1));" 0%");AGGREGAT(15;6;ZEILE(B$2:B$19)/(INDEX($B$2:$E$19;;ZEILE(A1))>0);SPALTE(A5)))&WENN(I5="";"";", "&I5);"") 


und diese Formel nach rechts ziehend kopieren und dann nach unten. Die Hilfsspalten I:J sind natürlich wieder ausblendbar.

[schluckspecht]

@neopa
Moin,
hat gut geklappt.Danke noch mal

[neopa]

Hallo nochmal,

wenn das Ergebnislsiting n Abhängigkeit von dem/den Namen in Spalte G erstellt werden soll, weil dort in G5 über z.B. einen Dropdownzelle ein Name aus B1:F1 in beliebiger Sortierung steht, dann folgende Formel in H5:

PHP-Code:

=WENNFEHLER(INDEX($A$1:$A$99&TEXT(INDEX($B$1:$E$99;;VERGLEICH($G5;$B$1:$E$1;0));" 0%");AGGREGAT(15;6;ZEILE(B$2:B$99)/($B$2:$E$99>0)/($B$1:$E$1=$G5);SPALTE(A5)))&WENN(I5="";"";", "&I5);"") 


und diese nach rechts und unten kopieren

[RPP63]

Moin!
"Außer Konkurrenz" mal die Variante, wie ich das mit meinem Excel 365 angehen würde:
► die Kreuztabelle mittels PowerQuery entpivotieren
► aus dieser Liste wird ein Pivot erstellt:
► Namen und Stadt in Zeilen
► Wert in Werte
► Stadt, Wertefilter, größer als 0
► Wert, Werte anzeigen als, Optionen, Zahlenformat, Prozent

ergibt:
   

oder einfach die entpivotierte Tabelle nach >0 filtern:

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C
1	Namen	Attribut	Wert
3	Müller	Berg. Gladbach	33%
7	Müller	Saarbrücken	67%
12	Heinrich	Neuss	50%
13	Heinrich	Recklinghausen	50%
19	Schulze	Neuss	33%
22	Schulze	Siegen	67%
24	Becker	Berg. Gladbach	33%
27	Becker	Recklinghausen	33%
29	Becker	Siegen	33%
35	Kleeberg	Saarbrücken	50%
36	Kleeberg	Siegen	50%
37	Fries	Aachen	100%
45	Everett	Berg. Gladbach	50%
49	Everett	Saarbrücken	50%

---

Und da es mich gejuckt hat (Excel 365 oder Excel-Online):

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	I	J
1	Namen	Attribut	Wert		Namen	Kette
2	Müller	Aachen	0%		Becker	Berg. Gladbach 33%, Recklinghausen 33%, Siegen 33%
3	Müller	Berg. Gladbach	33%		Everett	Berg. Gladbach 50%, Saarbrücken 50%
4	Müller	Hildesheim	0%		Fries	Aachen 100%
5	Müller	Neuss	0%		Heinrich	Neuss 50%, Recklinghausen 50%
6	Müller	Recklinghausen	0%		Kleeberg	Saarbrücken 50%, Siegen 50%
7	Müller	Saarbrücken	67%		Müller	Berg. Gladbach 33%, Saarbrücken 67%
8	Müller	Siegen	0%		Schulze	Neuss 33%, Siegen 67%
9	Heinrich	Aachen	0%
10	Heinrich	Berg. Gladbach	0%

Zelle	Formel
I2	=SORTIEREN(EINDEUTIG(Tabelle1_2[Namen]))
J2	=TEXTVERKETTEN(", ";;FILTER(Tabelle1_2[Attribut]&TEXT(Tabelle1_2[Wert];" 0%");(Tabelle1_2[Namen]=I2)*(Tabelle1_2[Wert]>0)))

[PIVPQ]

Hallo

@ RPP63

Das war war auch mein Gedanke deinen Vorschlag.
Doch Mac hat Probleme mit PQ.

[schluckspecht]

Hallo noch mal,
Die Formel die mir Neopa für das verwenden über die Dropdownauswahl
zu Verfügung gestellt hat,klappt im Blatt 1 wunderbar.
Nun wollte ich dies auf Blatt 2 anwenden.Über die Städteauswahl funktioniert es auch.
Aber über die Namensauswahl nicht.
Im Grunde müsste doch nur die Formel bei der Städteuswahl modefiziert werden.
Aber da ist der Wurm drin.Ich bekomme es nicht hin.
Wer kann mich dahin nochmal unterstützen?

Danke

[neopa]

Hallo,

dafür muss die Formel etwas anders angepasst werden. Folgende Formel in K17

PHP-Code:

=WENNFEHLER(INDEX($A$1:$H$1&TEXT(INDEX($A:$H;VERGLEICH($J17;$A:$A;0););" 0%");AGGREGAT(15;6;SPALTE($B2:$H2)/($A$2:$A$19=$J17)/($B2:$H19>0);SPALTE(A2)))&WENN(L17="";"";", "&L17);"") 


und diese nach rechts ziehend kopieren.