Zeilenblöcke anhand Grunddaten erstellen und transportieren

[Bookshelf3011]

Hallo alle zusammen und einen schönen Abend,

ich würde gerne versuchen, anhand von minimalen Grunddaten eine Gruppe von Zeilen und Spalten zu erzeugen und diese in ein anderes Tabellenblatt transportieren.
Wenn möglich möchte ich dies über einen Button lösen.

Beispiel:

Schritt 1:
Man benennt einen Schacht (alles in Tabellenblatt 1) und gibt an, wie viele Rohre von diesem abgehen.

   

Drückt man den Button soll folgendes passieren...

Schritt 2:

Jedes Rohr besteht aus einer immer gleichen Anzahl von Subrohren (in diesem Beispiel 10). Diese sollen in Tabellenblatt 2 mit den Informationen aus Tabellenblatt 1
untereinander geschrieben werden.

   

Schritt 3:

Hat man mehrere Schächte in Tabellenblatt 1 stehen, sollen diese sich automatisch in die nächsten freien Zeilen einfügen.

   

   

Hinzu sei noch gesagt, dass die Spalten, in die die Inhalte eingefügt werden, fixiert sind und es hier keine Verschiebungen gibt.

Kann mir jemand sagen, ob dies generell möglich ist und wenn ja, in welche Richtung ich mein Augenmerk richten soll?

Einen schönen Abend...

Mit freundlichem Gruß

Bookshelf3011

[GMG-CC]

Kopfschüttel, zweiter verstärkter Gang.
Ich verweise einfach einmal auf die erste Antwort dieses http://www.clever-excel-forum.de/thread-9427.html wo Peter etwas in Sachen "Bildchen" gesagt hat. Also noch einmal: Bilder gehören in eine Galerie!

[Kuwer]

Hallo Bookshelf3011,

teste es mal damit. Die Zeile ist hier von der aktiven Zelle abhängig.

Modul Modul1

Option Explicit 



Sub Makro2() 

 Dim i As Long, j As Long 

 Dim lngSubrohre As Long 

 Dim varQ As Variant, varZ As Variant 

  

 lngSubrohre = 10 

 varQ = Cells(ActiveCell.Row, 1).Resize(, 5).Value 

 Redim varZ(1 To lngSubrohre * varQ(1, 5), 1 To 7) 

  

 For i = 1 To varQ(1, 5) 

   For j = 1 To lngSubrohre 

     varZ(i * lngSubrohre - lngSubrohre + j, 1) = varQ(1, 1) 

     varZ(i * lngSubrohre - lngSubrohre + j, 2) = varQ(1, 2) 

     varZ(i * lngSubrohre - lngSubrohre + j, 3) = varQ(1, 3) 

     varZ(i * lngSubrohre - lngSubrohre + j, 4) = "Rohr" 

     varZ(i * lngSubrohre - lngSubrohre + j, 5) = i 

     varZ(i * lngSubrohre - lngSubrohre + j, 6) = "Subrohr" 

     varZ(i * lngSubrohre - lngSubrohre + j, 7) = j 

   Next j 

 Next i 

  

 Worksheets("Tabelle2").Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(Ubound(varZ, 1), Ubound(varZ, 2)).Value = varZ 

  

End Sub 



VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 14 - mit VBAHTML 12.6.0

Gruß Uwe

[Bookshelf3011]

Hallo Kuwer,

vielen Dank für die schnelle Antwort. Der Code funktioniert wunderbar. 

@GMG-CC

Jetzt weiß ich was du meinst und werde mich ab sofort daran halten...Als im ersten Thread das "Galerie" stand, dachte ich, dass damit die Bilder im Attachment gemeint waren.
Fehler meinerseits erkannt und wird nicht wieder vorkommen.

Gruß und schönen Abend

Bookshelf3011