Wert in vorgesehene Zelle übertragen

[Julius2000]

Servus, 

ich habe folgende Mission: Ich habe eine Tabelle mit Datum (durchlaufend) (Spalten) und Namen (Zeilen).
Jetzt hätte ich gerne, dass man den Name und das Datum angeben kann und dann einen Wert, der per Knopfdruck in das entsprechende Feld kopiert wird.
Leider finde ich hierzu keine Tutorials, vielleicht hat hier jemand eine Idee.
Der Wert soll jeweils bei "soll" stehen. Ist wird durch Formeln befüllt

Vielen Dank
Julius

[UweD]

Hallo


in ein Modul

Code:

Sub Schaltfläche1_Klicken()
    Dim SP1 As Integer, ZE1 As Integer, Spalte As Integer, Zeile As Integer
    Dim NName As String, Datum As Date, Wert As Double
   
    SP1 = 1 'Spalte A
    ZE1 = 8 'zeile mit Datum
   
    With ActiveSheet
        NName = .Cells(2, 2)
        Datum = .Cells(3, 2)
        Wert = .Cells(4, 2)
       
        If WorksheetFunction.CountIf(.Rows(ZE1), Datum) > 0 Then
            Spalte = WorksheetFunction.Match(CDbl(Datum), .Rows(ZE1), 0)
       
            If WorksheetFunction.CountIf(.Columns(SP1), NName) > 0 Then
                Zeile = WorksheetFunction.Match(NName, .Columns(SP1), 0)
               
                .Cells(Zeile, Spalte) = Wert
            Else
                MsgBox "Name '" & NName & "':  nicht vorhanden"
            End If
       
        Else
            MsgBox "Datum '" & Datum & "':  nicht vorhanden"
        End If
   
    End With
   
End Sub

Das dann dem Button zuweisen

Desweiteren:
- markiere B4
- Daten, Datentools, Datenüberprüfung
- Zulassen: Liste
- Quelle: 0,25;0,50;0,75;1,00     eintragen
- OK



LG UweD