WENN mit UND Funktion

[bimbam1965]

Ich habe folgendes Problem. In einer Trainingseinheit wurde mir folgende Aufgabe gestellt. Filialleiter erhalten je nach Umsatz einen Bonus. Der Bonus beträgt 2% ab 300 000 Euro und 3% ab 500 000 Euro. Unter 300 000 Euro wird kein Bonus gezahlt. Die Auszahlung eines Bonus ist abhängig vom Alter. Ab 45 Jahren wird der Bonus gezahlt. Ich weiß, dass ich hier eine WENN-Funktion mit einer UND-Funktion koppeln muss. Leider komme ich immer mit den Klammern und den Semikolons durcheinander. Mir ist auch nicht ganz klar, wie ich die Funktion aufbauen muss.
In der Spalte C4 steht das Alter in der Spalte D4 steht der Umsatz und in der Spalte E4 soll die entsprechende Bonuszahlung in Prozent stehen.

[steve1da]

Hola,
=wenn(Betrag<300000;0;wenn(Betrag<500000;0,02;0,03))
Für die Altersabfrage braucht man kein UND weil man einfach zuerst abfragt ob das Alter <45 ist, dann "" und im Sonst Teil die erste Formel wieder benutzt.
Gruß,
steve1da

[BoskoBiati]

Hi,

die Aufgabenstellung ist schon nicht eindeutig, da nicht geklärt ist, ob es sich um einen Bonus auf die Gesamtsumme oder einen Staffelbonus dreht.
Abgesehen davon lautet die Vorgabe, die Aufgabe mit UND zu lösen, also machen wir das so:

Code:

=WENN(UND(C4>44;D4>=300000);(2+(D4>=500000))%;0)

[LCohen]

Es tendiert Richtung "Gesamtsumme". Bei "Staffel" hätte ich schon zugeschlagen.

[HKindler]

Hi,

ich pfeiffe auf die Aufgabenstellung. Da braucht man weder WENN noch UND sondern nur ein wenig Mathematik:
=(C4>44)*(D4>=300000)*(2+(D4>=500000))%

[LCohen]

Ich pfeiffe mal mit und nehme "Staffel": =SUMMENPRODUKT((D4%%>{0.30.50})*(D4%%-{0.30.50})*{0.3.-1})/1%*(C4>44)

[bimbam1965]

Ich habe nahezu eine Lösung gefunden
Die Formel lautet wie folgt:
=WENN(UND(C4>=$H$9;D4>=$H$5);WENN(UND(C4>=$H$9;D4>=$H$4);$I$4;$I$3))
Irgendwo ist hier eine Klammer falsch gesetzt. Vielleicht kann mir jemand helfen.

[steve1da]

Danke für das Feedback zu unseren Vorschlägen.
Bei deiner Formel ist keine Klammer falsch gesetzt.

[schauan]

Hallöchen,

falls Du im FALSE-Teil des äußeren WENN etwas erwartest, da hast Du nix definiert.

[bimbam1965]

Ich habe jetzt die Lösung gefunden
Die Formel lautet wie folgt:
=WENN(UND(C4>=$H$9;D4>=$H$5);$I$5;WENN(UND(C4>=$H$9;D4>=$H$4);$I$4;$I$3))
Ich hatte bei der ersten WENN Funktion vergessen einen Dann Wert einzugeben.
Vielen Dank für eure Unterstützung.