Von zwei Zellen aus bearbeiten

[Erzin24]

Hallo alle zusammen, 

ich überlege gerade es ob es die Möglichkeit gibt eine Wechselbeziehung zwischen zwei Zeilen zu erstellen. 

Das heißt: Ich kann in der Tabelle 1 E4 eine Zahl eingeben, welche dann auch in der Tabelle 2 D5 zu sehen ist. Andersherum möchte ich jederzeit einen Wert in der Tabelle 2 D5 eingeben, welcher in der ersten Tabelle übernommen wird. 

Ich glaube, dass ich es ohne VBA/Makro nicht schaffe. 
Oder doch? 


Ich freue mich auf Eure Denkanstöße. 

LG 
Erzin24

[UweD]

Hallo

- Alt+F11
- Strg+R
- doppelckick auf DieseArbeitsmappe
- rechts dann diesen Code eintragen

Code:

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    Const APPNAME = "Workbook_SheetChange"
    On Error GoTo Fehler
   
    Dim TB1 As Worksheet, TB2 As Worksheet, RNG1 As Range, RNG2 As Range
       
    Set TB1 = Sheets("Tabelle1")
    Set TB2 = Sheets("Tabelle2")
    Set RNG1 = TB1.Range("E4")
    Set RNG2 = TB2.Range("D5")
   
    If Sh.Name = TB1.Name And Target.Address = RNG1.Address Then
        Application.EnableEvents = False
        RNG2 = Target.Value
    End If
   
    If Sh.Name = TB2.Name And Target.Address = RNG2.Address Then
        Application.EnableEvents = False
        RNG1 = Target.Value
    End If
   
    '*** Fehlerbehandlung
    Err.Clear
Fehler:
    Application.EnableEvents = True
    If Err.Number <> 0 Then MsgBox "Fehler in Sub """ & APPNAME & """" & vbCrLf _
        & "Fehlernummer: " & Err.Number & vbLf & Err.Description: Err.Clear
   
End Sub

 

LG UweD

[Erzin24]

Perfekt. Danke!

Jetzt kann ich mich mal an deinen Code arbeiten um das ganze besser zu verstehen.


Schönen Abend noch. 
LG