Das Clever-Excel-Forum.de - Treffen
... 14.-16. September 2018 im Allgäu ...

Verketten ?
#1
Hallo Leute ich bin neu hier und ich hoffe ihr könnt mir Helfen,

Da ich nicht so der Excel Profi bin und bisher alles was ich bisher in meiner Excel tabelle geschafft habe über die office apps von android bzw. über open office gemacht habe hoffe ich das ihr mir trotzdem helfen könnt.

Nun zu meinem Problem:

Ich möchte gerne das auf der Seite Bremszettel in der Zeile 17 Spalte F-J eine Verkettung aus Zahlen Steht die in ihrer Position in dem Tabellenblatt Wagenliste immer in den spalten D-H stehen und nur in ihrer höhe in der tabelle variieren und von den gesammt eingegebenen daten brauche ich immer den letzten Eintrag aus den spalten D-H verkettet.

ich hoffe das ich es jetzt nicht zu kompliziert gemacht habe.

ich habe die Datei zum bearbeiten angehängt

Danke euch im vorraus sorry für meine Rechtschreibung schreibe von mobil aus


Angehängte Dateien
.xlsx   Wagenliste vers. TEST.xlsx (Größe: 48,22 KB / Downloads: 10)
to top
#2
Hi,

hab ich dich richtig verstanden?

Bremszettel

CDEFGHIJ
167a  Nummer des Ersten Fahrzeugs60 56 7890 123-4
177b  Nummer des Letzten Fahrzeugs344556788901
Formeln der Tabelle
ZelleFormel
F17=VERWEIS(2;1/(Wagenliste!$D20:$D49<>"");Wagenliste!$D20:$D49)&VERWEIS(2;1/(Wagenliste!$E20:$E49<>"");Wagenliste!$E20:$E49)&VERWEIS(2;1/(Wagenliste!$F20:$F49<>"");Wagenliste!$F20:$F49)&VERWEIS(2;1/(Wagenliste!$G20:$G49<>"");Wagenliste!$G20:$G49)&VERWEIS(2;1/(Wagenliste!$H20:$H49<>"");Wagenliste!$H20:$H49)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Lass bloß die verbundenen Zellen bleiben - als Überschriften ja ganz OK, aber nicht, wenn in den Zellen Berechnungen stattfinden sollen. Lies dir dazu bitte mal diesen Beitrag durch: http://www.clever-excel-forum.de/Thread-...oder-Segen
Gruß Günter
Misserfolg ist eine Chance, es beim nächsten Mal besser zu machen.
(Henry Ford) http://www.sprueche-zum-nachdenken.eu
to top
#3
Hallo cantus

Keine Ahnung welche Version "Office Mobile" ist aber mit der allerneuesten Version von Office365 geht das:
Code:
=TEXTVERKETTEN("";WAHR;INDEX(Wagenliste!$D:$H;VERWEIS("Ω";Wagenliste!$D$20:$D$49;ZEILE(Wagenliste!$D$20:$D$49));0))
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
to top
#4
Hallo, so..:


Arbeitsblatt mit dem Namen 'Bremszettel'
 CDEFGHIJ
167aNummer des Ersten Fahrzeugs60 56 7890 123-4
177bNummer des Letzten Fahrzeugs34 45 5678 890-1

ZelleFormel
F16=VERKETTEN(TEXT(WENN(Wagenliste!G20=""; ;Wagenliste!D20);"00");" ";TEXT(Wagenliste!E20;"00");" ";TEXT(Wagenliste!F20;"0000");" ";TEXT(Wagenliste!G20;"000");"-";TEXT(Wagenliste!H20;"0"))
F17=VERWEIS(2;1/(Wagenliste!D20:D49<>"");Wagenliste!D20:D49)&" "&VERWEIS(2;1/(Wagenliste!E20:E49<>"");Wagenliste!E20:E49)&" "&VERWEIS(2;1/(Wagenliste!F20:F49<>"");Wagenliste!F20:F49)&" "&VERWEIS(2;1/(Wagenliste!G20:G49<>"");Wagenliste!G20:G49)&"-"&VERWEIS(2;1/(Wagenliste!H20:H49<>"");Wagenliste!H20:H49)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
cu Jörg eine Rückmeldung wäre ganz reizend XL2003 bis XL2013
[-] Folgende(r) 1 Benutzer sagt Danke an Jockel für diesen Beitrag:
  • cantus
to top
#5
Hallo,

ich würde in einer Hilfsspalte in der Wagenliste die Nummer bilden und dann über Verweis darauf zugreifen. Ergibt dann die beiden Formeln:

Wagenliste AE

Code:
=WENN(D20="";"";D20&" "&E20&" "&F20&" "&G20&"-"&H20)

Und Bremszettel:

Code:
=VERWEIS(9;1/(Wagenliste!AE20:AE49<>"");Wagenliste!AE20:AE49)
Gruß
Opa Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
to top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste