Das Clever-Excel-Forum.de - Treffen
... 14.-16. September 2018 im Allgäu ...

Vergleich 2 Zellen
#1
Hallo Excel-Profis Smile

Ich habe ein Problemchen, an dem ich mir grad die Zaehne ausbeisse:

Gegeben:
2 Zellen. In denen laeuft je eine Berechnung und erzeugen je nach Parameter versch. Ergebisse.
Finale Ausgabe in einer dritten Zelle, hier soll wenn
Zelle1<500 der Wert von Zelle1 stehen (z.B. 450).
Zelle1>=500 und Zelle2>=500 der Wert von Zelle2 stehen (z.B. 700).
Zelle1>=500 und Zelle2<500 ein fester Wert von 500 stehen.

Wie bekomme ich sowas hin (keine Makros)?

Vielen Dank schonmal! Smile


Chris
to top
#2
Hi Chris, meinst du so..?


PHP-Code:
=WENN(A14<500;A14;WENN(UND(A14>=500;B14>=500);B14;WENN(UND(A14>=500;B14<500);500;""))) 
Arbeitsblatt mit dem Namen 'Tabelle3'
 ABC
14450850450
15505700700
16505300500

ZelleFormel
C14=WENN(A14<500;A14;WENN(UND(A14>=500;B14>=500);B14;WENN(UND(A14>=500;B14<500);500;"")))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
cu Jörg eine Rückmeldung wäre ganz reizend XL2003 bis XL2013
[-] Folgende(r) 1 Benutzer sagt Danke an Jockel für diesen Beitrag:
  • Chris_EDNC
to top
#3
Hallo

Und für diejenigen mit ganz aktuellen Excel-Versionen (>=16.0.6528.1011):
Code:
=WENNS(A14<500;A14;B14>=500;B14;WAHR;500)
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
[-] Folgende(r) 1 Benutzer sagt Danke an shift-del für diesen Beitrag:
  • Chris_EDNC
to top
#4
Hallo,

ohne WENN(S):


Code:
=(F11<500)*F11+(F11>=500)*((G11>=500)*G11+(G11<500)*500)
=(F11<500)*F11+(F11>=500)*MAX(G11;500)
=MAX(F11;(F11>=500)*MAX(G11;500))
Gruß
Opa Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
[-] Folgende(r) 1 Benutzer sagt Danke an BoskoBiati für diesen Beitrag:
  • Chris_EDNC
to top
#5
Hallo Edgar

Deine letzte Variante ist bisher die beste. Nicht nur weil sie die kürzeste ist sondern auch weil sie nur 3 Zellbezüge und 3 Funktionen/Operatoren beinhaltet.
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
to top
#6
Super, es geht!!! Smile
Ich habe Jockels Loesung genommen. Die von Edgar habe ich nicht verstanden... Wink

Vielen Dank nochmals!


Chris
to top
#7
Hallo zusammen,

@Edgar

Dein letzter Vorschlag rechnet nicht korrekt:

Tabelle3

ABCGH
1Edgar IIIFormel ergibt:
2505300505505=MAX(A2;(A2>=500)*MAX(B2;500))
3=MAX(505;(WAHR(1))*500))
4=MAX(505;500)=505
Formeln der Tabelle
ZelleFormel
C2=MAX(A2;(A2>=500)*MAX(B2;500))
G2=MAX(A2;(A2>=500)*MAX(B2;500))
H2=FORMELTEXT(G2)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Gruß Günter
Misserfolg ist eine Chance, es beim nächsten Mal besser zu machen.
(Henry Ford) http://www.sprueche-zum-nachdenken.eu
to top
#8
Hallo Günter,

dann ist wohl gestern beim Testen was schiefgelaufen. Die kürzeste Version ist wohl doch mit WENN:


Code:
=WENN(A5<500;A5;MAX(B5;500))
Gruß
Opa Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
to top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste