Variable von Modul zu Modul

[Herbert der Erste]

Guten Abend,

wie kann ich die text Variable zu einer FarbCode Variablen definieren?

In "I5" steht ein Wert wie z.B.: vbCyan, vbBlue, usw.

1. Code:

Code:

Option Explicit

Sub Einloggen_Makro()

    Call HintergrundFarbe

    Worksheets("Dashboard").Cells.Interior.Color = HintergrundFarbeWert

End Sub

2. Code:

Code:

Option Explicit

Code:

Public HintergrundFarbeWert As Variant, SchriftFarbeWert As Variant

Sub HintergrundFarbe()

    HintergrundFarbeWert = Worksheets("Einstellungen").Range("I5").Value
   
    MsgBox "Farbe: " & HintergrundFarbeWert

End Sub

MfG
Herbert

[Gast 123]

Hallo

Dim HintergrundFarbe as Variant    
Da brauchst du nichts im Text umwandeln, wenn es im VBA Code "vbCyan" gibt setzt Excel selbst den richtigen Wert eim.  Probier es einfach mal aus.

mfg Gast 123

[Kuwer]

Hallo Herbert,

Code:

Option Explicit

Sub Einloggen_Makro()
  Worksheets("Dashboard").Cells.Interior.Color = HintergrundFarbe
End Sub

Function HintergrundFarbe() As Long
  Select Case Worksheets("Einstellungen").Range("I5").Value
    Case "vbBlack" ' 0x0 Schwarz"
      HintergrundFarbe = vbBlack
    Case "vbRed" ' 0xFF Rot
      HintergrundFarbe = vbRed
    Case "vbGreen" ' 0xFF00 Grün
      HintergrundFarbe = vbGreen
    Case "vbYellow" ' 0xFFFF Gelb
      HintergrundFarbe = vbYellow
    Case "vbBlue" ' 0xFF0000 Blau
      HintergrundFarbe = vbBlue
    Case "vbMagenta" ' 0xFF00FF Magenta
      HintergrundFarbe = vbMagenta
    Case "vbCyan" ' 0xFFFF00 Zyan
      HintergrundFarbe = vbCyan
    Case "vbWhite" '0xFFFFFF Weiß
      HintergrundFarbe = vbWhite
    Case Else
      HintergrundFarbe = xlNone
  End Select
End Function

Gruß Uwe

[Herbert der Erste]

Hallo Gast,

nein bei mir sagt Excel: "Typen unverträglich".

MfG
Herbert

---

Hallo Uwe,

vielen Dank! Genau sowas habe ich gesucht!

Einen schönen Abend noch!

MfG
Herbert

[Sulprobil]

Mein Vorschlag: analog
https://berndplumhoff.gitbook.io/sulprob...adeblotter