Das Clever-Excel-Forum.de - Treffen
... 14.-16. September 2018 im Allgäu ...

Sortieren mit Zwischenschritten
#1
Hallo zusammen!

Seit geraumer Zeit versuche ich nun, mein unten beschriebenes Problem zu lösen, bekomme es aber nicht hin. Deshalb wende ich mich mal hier an das Forum, mit der Hoffnung, jemand weiß eine Lösung dazu.
Folgende Situation:
Ich bin Lehrer und habe eine Excel-Tabelle, die mir alle erreichten Punkte aller Aufgaben löst, mir den prozentualen Anteil anzeigt und die Note errechnet. Soweit ist alles prima. Was mir aber fehlt, ist, dass sie mir die Schüler mit den erreichten Punkten auch sortiert. Nun könnte ich ja ganz einfach nach zwei Kriterien sortieren lassen (Anzahl der erreichten Punkte/entsprechender Schülername). Das ist aber nicht das, was ich will/brauche.
Ich brauche eine Übersicht auch mit den "Leerzeilen" der Punkte, die eben kein Schüler erreicht hat.

Bsp.: Schüler A hat 30 Punkte, B 27, C 25 erreicht. Eine Sortierung würde mir natürlich geben:
A 30
B 27
C 25

Ich hätte aber gerne folgende Übersicht:
30 Schüler A  (insofern 30 die maximale Punktzahl wäre)
29,5
29
28,5
28
27,5
27 Schüler B
...
...

Klar könnte ich das - wie alles andere auch - ja theoretisch per Hand eingeben...aber es wäre natürlich praktischer, Excel würde mir das direkt so erstellen.
Gibt es da eine Lösung für?
Ich hoffe, ich konnte mein Problem klar genug formulieren?

Liebe Grüße
to top
#2
Hi,

bitte stelle uns eine Mustertabelle vor. Sie muss vom Aufbau, Formeln etc. her deinem Original entsprechen - Namen einfach anonymisieren. Hier kannst du nachlesen, wie das geht:  http://www.clever-excel-forum.de/Thread-...ng-stellen
Gruß Günter
Misserfolg ist eine Chance, es beim nächsten Mal besser zu machen.
(Henry Ford) http://www.sprueche-zum-nachdenken.eu
to top
#3
Moin!
Wenn alle Schüler unterschiedliche Punktzahlen erreichen, ist es einfach:

ABCDE
1SchülerPkt.Pkt.Schüler
2A3030A
3B2729,5
4C2529
528,5
628
727,5
827B
926,5
1026
1125,5
1225C
1324,5
Formeln der Tabelle
ZelleFormel
E2=WENNFEHLER(INDEX(A:A;VERGLEICH(D2;B:B;0));"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Schwieriger wird es, wenn Schüler gleiche Pkt. erreichen.
Wie soll die Darstellung dann erfolgen?

Gruß Ralf
to top
#4
(22.03.2016, 11:34)RPP63 schrieb: Moin!
Wenn alle Schüler unterschiedliche Punktzahlen erreichen, ist es einfach:

ABCDE
1SchülerPkt.Pkt.Schüler
2A3030A
3B2729,5
4C2529
528,5
628
727,5
827B
926,5
1026
1125,5
1225C
1324,5
Formeln der Tabelle
ZelleFormel
E2=WENNFEHLER(INDEX(A:A;VERGLEICH(D2;B:B;0));"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Schwieriger wird es, wenn Schüler gleiche Pkt. erreichen.
Wie soll die Darstellung dann erfolgen?

Gruß Ralf


Hallo Ralf,

da mich dieses Problem auch interessiert, hätte ich die Schüler mit gleicher Punktzahl jeweils in benachbarten Zellen aufgeführt.

Ich habe auch schon etwas mit der Tabelle experimentiert.
Sinn würde es machen, wenn man irgendwo die Maximalpunktzahl eintragen kann und sich dann die Spalte D automatisch ausfüllt.
Gruß Conny Smile
_______________________________________________________________

Die Summe der Intelligenz auf unserem Planeten ist konstant, aber die Bevölkerung wächst!
to top
#5
Hallo,

für den Fall, dass mehrere Schüler die gleiche Punktzahle erreichen, könnten sie in der selben Reihe in benachbarten Spalten gezeigt werden.

Test-Scenario:

In Spalte A stehen die Namen, in Spalte B die erreichten Punkte.

Die Liste alle Punkte steht in Spalte G (g2: =30; g3: =g2-0,5)

In den Spalten H und weiter nach rechts werde die Namen für die erreichten Punkte eingetragen.

Zuerst finden der relevanten Zeile:

H2: =aggregat((14;6;zeile($b$2:$b$letzte Zeile)*($b$2:$b$letzte zeile=$g2);1)

Diese Formel nach unten zeihen/kopieren.
G2 nach h2 kopieren und die letzte 1 durch eine 2 ersetzen, für jede weitere Spalte das 'k' jeweils um 1 erhöhen.

Die Namen werden durch =index($a$1:$a$letzte Zeile: die aggregat-Funktion;1) bestimmt.

Mfg
to top
#6
Moin!
Hier mal eine Lösung mit Matrixformeln:
Formel aus F2 kann nach rechts und unten gezogen werden.

ABCDEFGHIJK
1SchülerPkt.Pkt.Schüler1Schüler2Schüler3Schüler4MaxPkt:30
2A3030AF
3B2729,5
4C2529
5D2728,5
6E2628
7F3027,5
8G2727BDG
926,5
1026E
1125,5
1225C
1324,5
Formeln der Tabelle
ZelleFormel
D2=K1
E2=WENNFEHLER(INDEX(A:A;VERGLEICH(D2;B:B;0));"")
F2{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$1000=$D2;ZEILE($1:$1000));SPALTE(B1)));"")}
G2{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$1000=$D2;ZEILE($1:$1000));SPALTE(C1)));"")}
H2{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$1000=$D2;ZEILE($1:$1000));SPALTE(D1)));"")}
D3=WENN((D2-0,5)>=0;D2-0,5;"")
E3=WENNFEHLER(INDEX(A:A;VERGLEICH(D3;B:B;0));"")
F3{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$1000=$D3;ZEILE($1:$1000));SPALTE(B2)));"")}
G3{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$1000=$D3;ZEILE($1:$1000));SPALTE(C2)));"")}
H3{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$1:$B$1000=$D3;ZEILE($1:$1000));SPALTE(D2)));"")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf
to top
#7
Hab meine Übungsdatei mal angehängt.

Gruß Ralf


Angehängte Dateien
.xlsx   Sortierung horizontal.xlsx (Größe: 9,75 KB / Downloads: 3)
to top
#8
Hi,

die Lösung von Ralf ist gut, jetzt wäre es aber noch interessant, das so weit zu automatisieren, daß die Zeile 2 ebenfalls per Formel ausgefüllt würde (max. Schülerzahl in A), falls es mal mehr als 4 Schüler mit gleicher Punktzahl gibt, es könnten ja theoretisch alle Schüler die gleiche Punktzahl haben.

Mir fehlt aber noch die Idee für eine WENN in Zeile 2:

Schüler-Punkte
ABCDEFGHIJKL
1MaxPkt:30
2SchülerPkt.Pkt.Schüler 1Schüler 2Schüler 3Schüler 4Schüler 5   
3A3030AF
4B2729,5
5C2529
6D2728,5
7E2628
8F3027,5
9G2727BDGHIJ
10H2726,5
11I2726E
12J2725,5
1325C
1424,5

verwendete Formeln
Zelle Formel Bereich N/A
E2:I2="Schüler " & SPALTE(E2)-SPALTE($D$2)
D3=D1
D4=WENN((D3-0,5)>=0;D3-0,5;"")
E3:E14=WENNFEHLER(INDEX(A:A;VERGLEICH(D3;B:B;0));"")
F3:L14{=WENNFEHLER(INDEX($A:$A;KKLEINSTE(WENN($B$2:$B$1001=$D3;ZEILE($2:$1001));SPALTE(B2)));"")}$F$3
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

Excel-Inn.de
Hajo-Excel.de
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007
Add-In-Version 19.08 einschl. 64 Bit

Gruß Ralf

?mage

Die deutsche Rechtschreibung ist Freeware, d.h. du kannst sie kostenlos nutzen.
Allerdings ist sie nicht Open Source, deswegen darfst du sie nicht verändern oder in veränderter Form veröffentlichen.
to top
#9
Hi Ralf!  19
So (ab E2)?
=WENN(ANZAHL2($A3:$A1001)>=SPALTE(A1);"Schüler "&SPALTE(A1);"")

Gruß Ralf
to top
#10
Ich hab die Datei nochmal erweitert.
Neue Klassenarbeit wird jetzt mit F9 "gemischt".  05
Der Zufall wird auch abhängig von der max. Pkt.-Zahl gesteuert.
=ZUFALLSBEREICH(D$36*2;D$3*2)/2

Gruß Ralf


Angehängte Dateien
.xlsx   Sortierung horizontal.xlsx (Größe: 26,42 KB / Downloads: 3)
to top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste