Registriert seit: 08.05.2017
Version(en): 2007
Hallo,
ich habe eine Tabelle, die folgendermaßen aufgebaut ist:
Spalte A / Spalte B
Name: / Günther
Straße: / Goethe
Hausnummer: / 5
Hunderte dieser Datensätze untereinander. Ich bräuchte aber:
Name: / Straße: / Hausnummer:
Günther / Goethe / 5
Kann jemand einem blutigen Amateur helfen?
Gruß - robsn
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
Hi,
so?
Tabelle1 | A | B | C | D | E |
1 | | | Name | Straße | Hausnr. |
2 | Name | Günther | Günther | Goethe | 5 |
3 | Straße | Goethe | Friedrich | Schiller | 7 |
4 | Hausnr | 5 | Marx | Grünbaum | 2 |
5 | Name | Friedrich | Engels | Schumacher | 1 |
6 | Straße | Schiller | 0 | 0 | 0 |
7 | Hausnr | 7 | 0 | 0 | 0 |
8 | Name | Marx | 0 | 0 | 0 |
9 | Straße | Grünbaum | 0 | 0 | 0 |
10 | Hausnr | 2 | | | |
11 | Name | Engels | | | |
12 | Straße | Schumacher | | | |
13 | Hausnr | 1 | | | |
Formeln der Tabelle |
Zelle | Formel | C2 | =INDEX($B:$B;ZEILE()*3-6+SPALTE()-1) | D2 | =INDEX($B:$B;ZEILE()*3-6+SPALTE()-1) | E2 | =INDEX($B:$B;ZEILE()*3-6+SPALTE()-1) |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Folgende(r) 1 Nutzer sagt Danke an WillWissen für diesen Beitrag:1 Nutzer sagt Danke an WillWissen für diesen Beitrag 28
• robsn
Registriert seit: 08.05.2017
Version(en): 2007
Super! Danke dir - auf den ersten Blick funktioniert es mit der Beispieltabelle.
Ich versuche mal hinter den Befehl zu steigen und markiere dann hoffentlich alsbald als erledigt! Jeden Tag etwas lernen!
Registriert seit: 08.05.2017
Version(en): 2007
Puh, ich hab jetzt ein bissl dran geknabbert. Mein erster Post zeigte ein Beispiel. Meine tatsächliche Tabelle ist etwas komplizierter und ich krieg es einfach nicht angepasst, da ich nicht ganz hinter den Befehl steige.
Darf ich erneut um Hilfe betteln? Tatsächlich sieht sie so aus:
Tabelle1 | A | B |
1 | Firma: | Jacobi Autoteile GmbH |
2 | Anschrift: | Rottstraße 9 |
3 | PLZ: | 52068 |
4 | Ort: | Aachen |
5 | Telefon: | (02 41) 94 95 96-0 |
6 | eMail: | info@jacobi-autoteile.de |
7 | web: | www.jacobi-autoteile.de |
8 | Entfernung: | 3,00 km |
9 | | |
10 | Firma: | Günter Kloubert GmbH |
11 | Anschrift: | Tempelhofer Str. 10 |
12 | PLZ: | 52068 |
13 | Ort: | Aachen |
14 | Telefon: | (0241) 165888 |
15 | eMail: | info@guenter-kloubert.de |
16 | web: | www.guenter-kloubert.de |
17 | Entfernung: | 3,51 km |
18 | | |
19 | Firma: | Autolackierung Gottschalk |
20 | Anschrift: | Roderweg 6 |
21 | PLZ: | 52072 |
22 | Ort: | Aachen |
23 | Telefon: | (0241) 172508 |
24 | eMail: | autolackgottschalk@t-online.de |
25 | web: | www.autolack-gottschalk.de |
26 | Entfernung: | 4,83 km |
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Registriert seit: 04.04.2017
Version(en): 2013
08.05.2017, 14:49
(Dieser Beitrag wurde zuletzt bearbeitet: 08.05.2017, 14:49 von Jonas0806.)
Hallo,
diese Formel in C2 und nach unten und rechts ziehen:
Code:
=INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=C$1);ZEILE(A1)))
Vergessen zu sagen,
in C1:J1 stehen ""Firma:", "Anschrift:" usw...
Gruß Jonas
Folgende(r) 1 Nutzer sagt Danke an Jonas0806 für diesen Beitrag:1 Nutzer sagt Danke an Jonas0806 für diesen Beitrag 28
• robsn
Registriert seit: 10.04.2014
Version(en): Office 2019
08.05.2017, 15:27
(Dieser Beitrag wurde zuletzt bearbeitet: 08.05.2017, 15:27 von Jockel.)
Hallo, ich würde noch WENNFEHLER() umzutun, und richtige links daraus machen..: Jetzt sollte es gehen..:
Arbeitsblatt mit dem Namen 'Blatt1' |
| E | F | G | H | I | J | K | L |
1 | Firma: | Anschrift: | PLZ: | Ort: | Telefon: | eMail: | web: | Entfernung: |
2 | Jacobi Autoteile GmbH | Rottstraße 9 | 52068 | Aachen | (02 41) 94 95 96-0 | info@jacobi-autoteile.de | http://www.jacobi-autoteile.de | 3,00 km |
3 | Günter Kloubert GmbH | Tempelhofer Str. 10 | 52068 | Aachen | (0241) 165888 | info@guenter-kloubert.de | http://www.guenter-kloubert.de | 3,51 km |
4 | Autolackierung Gottschalk | Roderweg 6 | 52072 | Aachen | (0241) 172508 | autolackgottschalk@t-online.de | http://www.autolack-gottschalk.de | 4,83 km |
Zelle | Formel |
E2 | =WENNFEHLER(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=E$1);ZEILE($A1)));"") |
F2 | =WENNFEHLER(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=F$1);ZEILE($A1)));"") |
G2 | =WENNFEHLER(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=G$1);ZEILE($A1)));"") |
H2 | =WENNFEHLER(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=H$1);ZEILE($A1)));"") |
I2 | =WENNFEHLER(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=I$1);ZEILE($A1)));"") |
J2 | =WENNFEHLER(HYPERLINK("mailto:"&INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=J$1);ZEILE($A1)));INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=J$1);ZEILE($A1))));"") |
K2 | =WENNFEHLER(HYPERLINK(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=K$1);ZEILE($A1))));"") |
L2 | =WENNFEHLER(INDEX($B$1:$B$26;AGGREGAT(15;6;ZEILE($A$1:$A$26)/($A$1:$A$26=L$1);ZEILE($A1)));"") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Gruß Jörg
ich muss mich erst wieder ganz langsam heran robben. Also bitte ich um Nachsicht
"Wer immer tut, was er schon kann, bleibt immer das, was er schon ist." - Henry Ford
Folgende(r) 2 Nutzer sagen Danke an Jockel für diesen Beitrag:2 Nutzer sagen Danke an Jockel für diesen Beitrag 28
• robsn, Rabe
Registriert seit: 08.05.2017
Version(en): 2007
Wow! Vielen Dank euch allen! Funktioniert alles bestens!
Dieses Forum wird gebookmarkt und weiterempfohlen! Ihr seid stark!
Thema erledigt!