Problem mit ={MIN(WENN(UND...))}

[sheady]

Hallo zusammen,

ich möchte gerne den Minimalwert aus einer Spalte ermitteln, aus der aber nur diejenigen zellen berücksichtigt werden, die 2 Bedingungen erfüllen:

die zelle ist nicht leer
und
in der nachbarzelle steht "ja"

meine formel sieht so aus

={MIN(WENN(UND(B:B="ja";A:A<>"");A:A))}

dabei kommt allerdings, egal ob eine zelle leer ist oder nicht, immer der wert 0 raus. interessanter weise funktioniert die formel einwandfrei, wenn man nur eine bedingung stellt, also

={MIN(WENN(B:B="ja";A:A))} und ={MIN(WENN(A:A<>"";A:A))}

nur in kombination mit der UND() funktion funktioniert es nicht. was mach ich falsch?

gruß

[steve1da]

Hola,

hier wird nicht mit UND gearbeitet, sondern mit *.

Code:

=MIN(WENN((B:B="ja")*(A:A<>"");A:A))

Gruß,
steve1da

[Hydronaut]

was mach ich falsch?

Alles.

Code:

=AGGREGAT(15;6;A1:A10/(B1:B10="ja")/(A1:A10<>"");1)

[sheady]

danke dir für die schnelle antwort!

überraschend einfach. gibt es da eine regel, wann das * zum einsatz kommt?

@ Detlef: Danke auch dir, weiß ich zu schätzen, aber wenn ich mir deine umständliche lösung angucke, kann ich nicht "alles" falsch gemacht haben ^^

[Hydronaut]

@ Detlef: Danke auch dir, weiß ich zu schätzen, aber wenn ich mir deine umständliche lösung angucke, kann ich nicht "alles" falsch gemacht haben ^^

Verwendung von UND statt *.
Verwendung von ganzen Spalten statt nur des benutzen Bereiches.
Unnötige Verwendung von {}.
Bei Einsatz der aktuellen Office 365-Version könntest du sogar MINWENNS() verwenden:

Code:

=MINWENNS(A1:A10;A1:A10;"<>";B1:B10;"ja")