Mittelwert dynamischer Bereich!

[Sceetch]

Hallo Stefan,

ich denke ich komm klar damit. Danke hierfür

Hätte noch ne Frage zu der Formel 
=WENN(ZEILE(B1)> ANZAHL2($B$4:$B$86); "";INDEX($B:$B; KKLEINSTE(WENN(B$4:B$86<>"";ZEILE($4:$86)); ZEILE(A1))))

ich kann diese über das Feld der Matrix nicht kopieren. Sie ändert sich nicht.

Ich markiere das Feld, gebe die Formel ein und bestätige mit shift+umschalt+enter. Die Formel wird zwar dann geklammeert aber die Zeilenwerte B1 und A1 bleiben gleich. 
Was mach ich falsch. Die müssten sich doch fortlaufend ändern?

Grüße

[Sceetch]

Glaube es liegt am Index:

=WENN(ZEILE(B1)> ANZAHL2($B$4:$B$86); "";INDEX($B:$B; KKLEINSTE(WENN(B$4:B$86<>"";ZEILE($4:$86)); ZEILE(A1))))

habe es jetzt so:
=WENN(ZEILE(B1)> ANZAHL2($B$4:$B$86); "";INDEX(B:B; KKLEINSTE(WENN(B$4:B$86<>"";ZEILE($4:$86)); ZEILE(A1))))

[StefanB]

Hallo,

probier mal:

Code:

{=WENN(ZEILE(B1)> ANZAHL2(B$4:B$86); "";INDEX(B:B; KKLEINSTE(WENN(B$4:B$86<>"";ZEILE($4:$86)); ZEILE($A1))))}

[Fred11]

Hallo Kuse,

anbei ein Lösungsansatz basierend auf deiner Beispieldatei aus #3

Arbeitsblatt mit dem Namen 'Durchschnitt'
	B	C	D	E	F	G	H	I	J	K	L	M	N	O
2			Januar						Februar
3	Mittelwert		1	2	3	4	5	6	1	2	3	4	5	6
4	5	Alex	6	7	0	6	0	0	0	6	0	1	0	0
5	5,5	Michael	0	4	3	0	0	0	4	7	7	0	4	0
6	5,75	Stefan	5	3	2	5	0	0	3	0	7	8	0	0

Zelle	Formel
B4	=WENN($C4<>"";MITTELWERTWENN(INDEX($D4:$BW4;AGGREGAT(14;6;SPALTE($D4:$BW4)*($D4:$BW4>0);4)-SPALTE($C4)):$BW4;"<>0");"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

  Stunden_Mittelwert dynamischer Bereich_fs.xlsx (Größe: 13,93 KB / Downloads: 4)

Der Ausdruck
   AGGREGAT(14;6;SPALTE($E4:$BX4)*($E4:$BX4>0);4)-SPALTE($D4)
ermittelt die Spaltennummer (im Bereich $E4:$BX4) des 4.-letzten Wertes, der größer 0 ist
(ist genau dasselbe, wie die Matrixformel mit KKLEINSTE bei der Lösung von StefanB)

Basierend auf der Beispieldatei von StefanB aus # 9 ein optimierter Lösungsansatz
Die Hilfstabelle (Spalten G:L) ist doch eigentlich gar nicht notwendig….

  Kopie von Stunden-1-1_fs.xlsx (Größe: 24,5 KB / Downloads: 5)

Gruß
Fred

[StefanB]

Moin Fred,

die Hilfsspalten sind tatsächlich nicht notwendig, aber Sie geben ein paar weitere Infos. Ob man die nun braucht oder nicht, sei mal dahingestellt.
Ich wollte halt die ganze Sache etwas aufdröseln um Sceetch zu zeigen welche Infos man noch aus so einer Auflistung rausholen kann...

[Sceetch]

Guten Morgen,

Danke Jungs. Das sind sehr schöne Vorschläge.
Fred's Vorschlag mit einfärben des letzten Wertes find ich super.

@Fred: Wie würde denn die Formel aussehen, wenn dies auf Spalten bezogen wird? Also quasi in Stefans Beispiel.
und nicht nur den vierten Wert markieren, sondern alle 4 relevanten werte?

Grüße
Kuse

[Fred11]

Hallo Kuse,

...Wie würde denn die Formel aussehen, wenn dies auf Spalten bezogen wird? ...

Bei der Formel für die bedingte Formatierung muss lediglich ...SPALTE... durch ZEILE ersetzt werden

Formel für bedingte Formatierung (für Bereich B4:D86) zum markieren der letzten 4 Werte::
=(ZEILE()>=AGGREGAT(14;6;ZEILE(B$4:B$86)*(B$4:B$86>0);4))*(B4<>"")

siehe angehängte Beispieldatei

Gruß
Fred

[Sceetch]

Super, 
verstanden.

Dankeschön @Fred & @Stefan!

von meiner Seite aus, ist das Thema erledigt.