Mitarbeiterstärke berechnen

[omron2003]

Hallo Forum,

ich baue mir gerade einen An/Abwesenheitsplaner für mehrere Schichten auf,
nun suche  ich eine Möglichkeit die anwesende Mitarbeiterstärke auszuwerden.
Wieviel Mitarbeiter stehen pro Kalendertag (Abteilung) zur Verfügung.
Im Anhang habe ich eine kleine Demo wie ich mir das mit der Auswertung vorstelle.
Wie könnte ich das eventuell mit einer Formel oder VBA realisieren?

Besten Dank im Voraus
Helmut

[HKindler]

Hi,

Auswertung!B5: =SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;Vorgaben!$A$13:$A$18))
runter und nach rechts ziehen

[omron2003]

Hi,

Super danke funktioniert einwandfrei,
habe aber etwas entscheidenes vergessen, es sollten auch die leeren Zellen aus dem Kalender wo keine Vorgaben Kürzel drin stehen mitgezählt werden,
da das ja die Mitarbeiter sind die keine anwesend/abwesend Auswahlkriterium bekommen. Lässt sich da an der Formel noch etwas machen?

Gruß
Helmut

---

Hi,

ich habe es jetzt so gemacht.

Code:

=SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;Vorgaben!$A$13:$A$18))+SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;""))

Ich hoffe das ist so OK?

Es scheint richtig zu rechnen.

Gruß
Helmut

[HKindler]

Hi Namenskollege,

wenn es richtig rechnet ist doch alles gut. Etwas einfacher wäre aber:
=SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;Vorgaben!$A$13:$A$18))+ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;"")

noch einfacher:
=SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;Vorgaben!$A$13:$A$18);ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;""))

und ganz einfach:
=SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;Vorgaben!$A$13:$A$19))
Wobei du dann die Zelle Vorgaben!A19 zuerst mit dem Zahlenformat Standard formatieren und dann die Formel ="" eintragen musst.

und am allereinfachsten:
=SUMME(ZÄHLENWENNS(Kalender!$A$5:$A$24;$A5;Kalender!C$5:C$24;Vorgaben!$A$13:$A$19&""))
Dann musst du nur dafür sorgen, dass die Zelle Vorgaben!A19 leer ist.

[omron2003]

Hi Helmut,
Danke für den Nachtrage und der professionelen Erklärung mit den Formel,
hier gilt wohl der Spruch "viele Wege führen zum Ziel".