Das Clever-Excel-Forum.de - Treffen
... 14.-16. September 2018 im Allgäu ...

Listen per Monat
#1
Hallo

habe ein Datum (register)
in denen Tage stehen und deren Inhalt.

Und ein List-Register
aus dem sollen sich für den angegebenen Monat die Tage anzeigen lassen
stehe mom aber auf dem schlauch wie ich das Lösen kann.

Also wenn im Datumsregister ein Datum Auftritt das in dem angegebenen Monat (a1) liegt,
soll des erste Datum in A2 erscheinen, das 2. Datum in A3 u.s.w.

Danke


Angehängte Dateien
.xlsx   Datum.xlsx (Größe: 9,48 KB / Downloads: 6)
to top
#2
Hallo

Arbeitsblatt mit dem Namen 'Liste'
 A
101.01.2016
207.01.2016
312.01.2016
421.01.2016
522.01.2016
626.01.2016
730.01.2016
8 
9 
1001.02.2016
1104.02.2016
1212.02.2016
1319.02.2016
1418.02.2016
1523.02.2016
16 
17 
18 
1901.03.2016
2003.03.2016
2108.03.2016
2217.03.2016
2322.03.2016
24 
25 
26 
27 

ZelleFormel
A2=WENNFEHLER(INDEX(Datum!$A:$A;AGGREGAT(15;6;ZEILE(Datum!$A$2:$A$16)/(MONAT(Datum!$A$2:$A$16)=MONAT(A$1));ZEILEN(A$2:A2)));"")
A11=WENNFEHLER(INDEX(Datum!$A:$A;AGGREGAT(15;6;ZEILE(Datum!$A$2:$A$16)/(MONAT(Datum!$A$2:$A$16)=MONAT(A$10));ZEILEN(A$11:A11)));"")
A20=WENNFEHLER(INDEX(Datum!$A:$A;AGGREGAT(15;6;ZEILE(Datum!$A$2:$A$16)/(MONAT(Datum!$A$2:$A$16)=MONAT(A$19));ZEILEN(A$20:A20)));"")
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
to top
#3
#shift-del 


Danke
wie kann ich das in Excel 2007 anwenden?
to top
#4
Zitat:wie kann ich das in Excel 2007 anwenden?
Etwas länger und etwas mehr Tastendrücke.
Arbeitsblatt mit dem Namen 'Liste'
 A
101.01.2016
207.01.2016
312.01.2016
421.01.2016
522.01.2016
626.01.2016
730.01.2016
8 
9 
1001.02.2016
1104.02.2016
1212.02.2016
1319.02.2016
1418.02.2016
1523.02.2016
16 
17 
18 
1901.03.2016
2003.03.2016
2108.03.2016
2217.03.2016
2322.03.2016
24 
25 
26 
27 

ZelleFormel
A2{=WENNFEHLER(INDEX(Datum!$A:$A;KKLEINSTE(WENN(MONAT(Datum!$A$2:$A$16)=MONAT(A$1);ZEILE(Datum!$A$2:$A$16));ZEILEN(A$2:A2)));"")}
A11{=WENNFEHLER(INDEX(Datum!$A:$A;KKLEINSTE(WENN(MONAT(Datum!$A$2:$A$16)=MONAT(A$10);ZEILE(Datum!$A$2:$A$16));ZEILEN(A$11:A11)));"")}
A20{=WENNFEHLER(INDEX(Datum!$A:$A;KKLEINSTE(WENN(MONAT(Datum!$A$2:$A$16)=MONAT(A$19);ZEILE(Datum!$A$2:$A$16));ZEILEN(A$20:A20)));"")}
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Wir sehen uns!
... shift-del
Hinweise zu meiner Hilfe in Foren
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
to top
#5
Hola,


@delenn: ging dir das hier nicht schnell genug?

http://ms-office-forum.net/forum/showthr...p?t=330189

Gruß,
steve1da
to top
#6
#shift-del 
Danke
genau das wars ;-)
to top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste