Leere Zellen überspringen

[StaBau11]

Hallo Liebe Gemeinde,

ich habe folgendes Problem:

Ich möchte gerne eine Formel erstellen die in A1 prüft ob dort "Feiertag" steht. Wenn es dort steht soll er bei der Auswertung diese Zelle nicht mit einbeziehen.

Ich habe vor damit eine Verkerhsrechtliche Anordnung zu schreiben. Ich benenne quasi das erste Datum mit "S1"   (z.B. so: S1 01.04.2021) 

Ich habe auch schon eine Formel hinterlegt die mir auswertet, wo Feiertage sind, denn diese müssen ausgeschlossen werden.
Nun will ich aber wenn er mir einen Feiertag auswertet das er diesen in der Reihenfolge S1, S2, S3, S4.... usw Überspringt. 

z.B. so:

S1      29.03.2021   Arbeitstag
S2      30.03.2021   Arbeitstag
S3      31.03.2021   Arbeitstag
S4      01.04.2021   Arbeitstag
         02.04.2021   Feiertag          
         03.04.2021   Wochenende
         04.04.2021   Wochenende
         05.04.2021   Feiertag
S5     06.04.2021   Arbeitstag



Die Roten Zahlen müssen also quasi in einer Spalte untereinander aufgezählt werden und eben dabei die Leeren Zellen überspringen.

Ich möchte nämlich diese Zellen mit Auto CAD verknüpfen. Das aber ist nicht das Problem.

Habe die Datei mal angehängt!

Vielen Dank im Vorraus!!

[steve1da]

Hola,

zuerst mal dein Formelmonster für die Feiertage ersetzen:

Code:

=WENN(ZÄHLENWENN(Feiertagsberechung!$B$4:$B$28;B2);"Feiertag";"")

Dann für die Auflistung:

Code:

=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($A$2:$A$54)/(($B$2:$B$54>=$F$2)*($C$2:$C$54<>"feiertag"));ZEILE(A1)));"")

Gruß,
steve1da

[StaBau11]

Danke für die Schnelle Antwort steve1da,

nun macht er aber leider die Datenreihenfolge kaputt in der S1,S2,S3 usw... er überspringt diese nun auch....es soll ja dennoch alle fortlaufenden Zahlen beinhalten. nur eben den Feiertag berücksichtigen.

Hab dir mal was als Beispiel angehängt 

Das Monster wurde entfernt :D

[StaBau11]

Hey nochmal,

gibt's schon ne Antwort für mich? :D

[Fred11]

Hallo StaBau11,

meinst du so ?

Arbeitsblatt mit dem Namen 'Datumsplanung'
	A	B	C	D	E
1	CAD Verknüpfung		Feiertag?
2		01.04.2021			S1
3		02.04.2021	Feiertag
4		03.04.2021	Wochenende
5		04.04.2021	Wochenende
6		05.04.2021	Feiertag
7		06.04.2021			S2
8		07.04.2021			S3
9		08.04.2021			S4
10		09.04.2021			S5
11		10.04.2021	Wochenende
12		11.04.2021	Wochenende
13		12.04.2021			S6
14		13.04.2021			S7

Zelle	Formel
C2	=WENN(WOCHENTAG(B2;2)>=6;"Wochenende";WENN(ZÄHLENWENN(Feiertagsberechung!$B$4:$B$28;B2);"Feiertag";""))
E2	=WENN(C2="";"S"&(ANZAHL2($E$1:E1)-ANZAHLLEEREZELLEN($E$1:E1)+2);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

siehe Beispieldatei

Gruß
Fred

[StaBau11]

Hallo StaBau11,

meinst du so ?

Arbeitsblatt mit dem Namen 'Datumsplanung'
	A	B	C	D	E
1	CAD Verknüpfung		Feiertag?
2		01.04.2021			S1
3		02.04.2021	Feiertag
4		03.04.2021	Wochenende
5		04.04.2021	Wochenende
6		05.04.2021	Feiertag
7		06.04.2021			S2
8		07.04.2021			S3
9		08.04.2021			S4
10		09.04.2021			S5
11		10.04.2021	Wochenende
12		11.04.2021	Wochenende
13		12.04.2021			S6
14		13.04.2021			S7

Zelle	Formel
C2	=WENN(WOCHENTAG(B2;2)>=6;"Wochenende";WENN(ZÄHLENWENN(Feiertagsberechung!$B$4:$B$28;B2);"Feiertag";""))
E2	=WENN(C2="";"S"&(ANZAHL2($E$1:E1)-ANZAHLLEEREZELLEN($E$1:E1)+2);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

siehe Beispieldatei

Gruß
Fred

Hallo Fred,

Exakt so! Vielen Dank dafür. jetzt muss ich nur noch rausfinden wie ich in einer weiteren spalte nun die leeren Zellen ausblenden lassen kann und da würde ich denn meine Auto CAD verknüpfung einfügen so das mir die leeren zellen erspart bleiben

Gruß Jan

[WillWissen]

Hi Jan,

du brauchst nicht vollzitieren, wenn klar ist, wer gemeint ist. "Normale" Antwort-Buttons findest du oberhalb und unterhalb des Antwortformulars jeweils auf der rechten Seite.

[steve1da]

Hola,

 wie ich in einer weiteren spalte nun die leeren Zellen ausblenden lassen kann

was soll denn am Ende genau überbleiben. Die Datumswerte und daneben die S-Werte, allerdings beides nur wenn beim S-Wert kein "" ist?
Gruß,
steve1da

[StaBau11]

Hallo,

ich hab da mal was angefügt wie es final aussehen soll.

[steve1da]

Hola,

für die S-Werte:

Code:

=WENNFEHLER(INDEX($E$2:$E$17;AGGREGAT(15;6;ZEILE($B$2:$B$17)-1/($E$2:$E$17<>"");ZEILE(A1)));"")

Für die Datumswerte:

Code:

=WENNFEHLER(INDEX($B$2:$B$17;AGGREGAT(15;6;ZEILE($B$2:$B$17)-1/($E$2:$E$17<>"");ZEILE(A1)));"")

Gruß,
steve1da