Jahres Abfall Kalender auf Basis des Jahreskalenders von Andreas Thehos

[Der Steuerfuzzi]

Da hat sich eine Copy-Paste-Fehler eingeschlichen. Hier die Korrektur:

Code:

Graue Tonne: =ARBEITSTAG(B7-WOCHENTAG(B7;3)+1-1;1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=1)=B7-(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7))>0)
Gelbe Tonne: =ARBEITSTAG(B7-WOCHENTAG(B7;3)+3-1;1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=1)=B7-(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7))>0)
Grüne Tonne: =ARBEITSTAG(B7-WOCHENTAG(B7;3)+1-1;1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=0)=B7-(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7))>0)

[Rabe]

Hi Michael,

und für die blaue Tonne so?

Code:

=ARBEITSTAG(B7-WOCHENTAG(B7;3)+1-1;1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);4)=3)=B7-(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7))>0)

[meierchen006]

Hallo Steuerfuzzi, Hallo Rabe,

Danke für Eure Unterstützung.

Auf die Formel für die blaue Tonne, bin ich auch dann auch selbst gekommen, auf  die 4 und 3 Tauschen wegen Kalenderwochen: 

Letztendlich nochmal danke, bin jetzt dabei die Formel auseinanderzuholen um zu verstehen was welcher Teil der Formel macht.

Habe mal verschiedene Jahreszahlen oben eingegeben, Beispiel 2019 dann 1. Kalenderwoche, da verschiebt sich der Abholtag auf Donnerstag für die graue Tonne,
ich Denke richtig wäre in diesem Fall der Mittwoch.

Ja das nächste mal wenn dem so ist, ist das Jahr 2030. 

Immer wenn der Feiertag auf den Abholtag fällt, wird aktuell in der Formel dann um zwei Tage verschoben, richtig wäre ein Tag.

[Der Steuerfuzzi]

Ich habe es mal umgestellt, konnte es aber noch nicht testen:
=ARBEITSTAG(B7-WOCHENTAG(B7;3)+(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<=B7))>0)+1-1;1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=1)=B7

Das wäre die Formel für die graue Tonne. Das für die anderen Tonnen solltes Du hinbekommen. Du musst nur den farblich markierten Teil jeweils in die Formeln einfügen.

Teste bitte mal, ob es so funktioniert.

[meierchen006]

Hallo Steuerfuzzi,

ich habe die vier Formeln mal eingefügt ist soweit perfekt, aber jetzt liegt ein Fehler im August 2018 KW33 vor.

Dort ist Mittwoch ein Feiertag, graue Tonne kommt Dienstag ist richtig, wird aber bei Donnerstag nochmal markiert also falsch.

Anbei mal nochmal die Excel Datei.

[Der Steuerfuzzi]

Code:

Graue Tonne: =ARBEITSTAG(B7-WOCHENTAG(B7;3)+1-1+(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7-WOCHENTAG(B7;3)+1))>0);1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=1)=B7
Gelber Sack: =ARBEITSTAG(B7-WOCHENTAG(B7;3)+3-1+(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7-WOCHENTAG(B7;3)+3))>0);1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=1)=B7
Grüne Tonne: =ARBEITSTAG(B7-WOCHENTAG(B7;3)+1-1+(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7-WOCHENTAG(B7;3)+1))>0);1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);2)=0)=B7
Blaue Tonne =ARBEITSTAG(B7-WOCHENTAG(B7;3)+1-1+(SUMMENPRODUKT((Feiertage_Saar_1>=B7-WOCHENTAG(B7;2)+1)*(Feiertage_Saar_1<B7-WOCHENTAG(B7;3)+1))>0);1;Feiertage_Saar_1)*(REST(KALENDERWOCHE(B7;21);4)=3)=B7

[meierchen006]

Hallo Steuerfuzzi,

herzlichen Dank nochmal jetzt funktioniert der Kalender wie er soll, geprüft bis 2030 mir sind keine Fehler mehr aufgefallen.

anbei nochmal die fertige Lösung für alle.

[Rabe]

Hi,

mir würde es jetzt noch gefallen, wenn die Standard-Abholtage und die Abstände nicht fest verdrahtet in den Formeln stehen, sondern durch Verweise auf Zellen veränderbar wären.

[meierchen006]

Hallo,

das war auch mein Gedanke da brauche ich aber etwas Zeit um das zu verwirklichen, vorausgesetzt ich bekomme es hin.

Am Ende wird es dann ein schöner Kalender, die Basis ist schon eine besondere!

Sobald Zeit ist werde ich anfangen es einzubauen!

[meierchen006]

Hallo,

habe das jetzt mal nach meinem Verständnis eingebaut.

Von Montag bist Donnerstag funktioniert es beim Restmüll auch, doch wenn ich als Abholtag Freitag (4) eingebe funktioniert es nicht mehr!

Andere Müllarten habe ich jetzt nicht getestet.