Inhalte bei bestimmten Farben übertragen

[Trabsi]

Das ist mal der Ausschnitt um den es geht. Mein Plan war eigentlich, alles was rot oder orange ist am nächsten Tag automatisch wieder bei den Terminen erscheinen zu lassen.

[Jockel]

Hallo, du bist ein kleiner Spaßvogel, gell?

[RPP63]

Moin!
Mal abseits des Spaßes:
Bevor ich doch etwas "mühsam" händisch einfärbe, weil ich es "nicht geschafft" habe, markiere ich die Zelle und "ziehe" sie am Zellrand in den nächsten Tag.
Oder nicht?

Gruß Ralf

[schauan]

Hallo Trabsi,

hier mal nach meinem Ansatz. Ich gehe jetzt mal davon aus, dass Du zu einem Startdatum alle Aufgaben einträgst und die Liste dann solange fortführst, bis die Aufgaben abgearbeitet sind. in dieser Liste kommen dann keine neuen Aufgaben dazu.

In der Spalte A wird in gleichem Abstand das Datum eingetragen.

In Spalte B stehen beim ersten Datum die Aufgaben und ab dem zweiten Datum dann die Formeln. Du gibst die eine neben dem Datum in der Zelle ein und ziehst sie dann solange nach unten, wie benötigt. Der Nachteil dieser Variante ist, dass bei erledigten Aufgaben Lücken entstehen können, da die Einträge immer wieder in der gleichen Zeile eines Datumsbereiches stehen.

In Spalte C trägst Du dann ein, ob die Aufgaben erledigt sind (ja) oder nicht (nein). Steht dort nichts, dann wird die Aufgabe erst mal gelb markiert. Soll sie in den nächsten Tag übernommen werden, müsstest Du "nein" hinschreiben.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Datum	Aufgabe	Erledigt
2	05. Mai	Essen	ja
3		Trinken	nein
4		Schlafen	nein
5
6	06. Mai
7		Trinken	nein
8		Schlafen	ja
9
10	07. Mai
11		Trinken

Zelle	Formel
B6	=WENN(C2="nein";B2;"")

Zelle	bedingte Formatierung...	Format
B2	1: =UND(B2<>"";C2="")	abc
B2	2: =C2="ja"	abc
B2	3: =C2="nein"	abc

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[Trabsi]

@ Ralf: Da hier immer mehrere Personen mitschreiben und sowas wie in den nächsten Tag kopieren evtl. vergessen soll es automatisch gehen. Außerdem ist das markieren mit den Farben dazu da um auf einen schnellen Blick sehen zu können, was erledigt ist und was nicht.

@schauan: Die Idee ist gar nicht schlecht. Es kommen allerdings täglich neue Aufgaben dazu. Aber man könnte ja einen festen Bereich für die automstische übernahme frei halten und die neuen Termine drunter schreiben. Diese müssten dann natürlich auch wieder angelegt sein wie der erste Bereich.

[schauan]

Hallo Trabsi,

mit einer Erweiterung um neue Aufgaben wäre dann eine VBA-Lösung angesagt. Man könnte einen Button installieren, der dann den neuen Tag beginnt und dabei die unerledigten Aufgaben nachzieht. Die Erledigung und die Färbung würde ich dabei aber wie in meinem Beispiel lassen.

Eine Alternative wäre aus meiner Sicht, die Aufgaben nicht nachzuziehen sondern einfach nur mit dem AutoFilter die erledigten auszublenden. Man könnte dann in der Spalte C statt dem ja und nein das Datum der Erledigung eintragen, sodass Du auch gleich in einer Zeile das Datum der Aufgabenstellung und deren Lösung hast..

[atilla]

Hallo,

ich habe da mal etwas vorbereitet.

diese Angaben sind in der Datei bei der letzten Speicherung und Schließung der Datei:

Arbeitsblatt mit dem Namen 'Tabelle1'   A B C 2 Datum Termine Status 3 29.05.2017     4   S. Wendo erledigt 5   Team erledigt 6   L. T Handball erledigt 7   Einkauf dringend 8   LJ. Logo erledigt 9   L. TK. Mutter-ging keiner dran offen 10   J. Waschtag erledigt 11   J.Montag von der schule abgemeldet erledigt
Name Bezug Status =Parameter!$A$2:$A$4	Zelle Gültigkeitstyp Operator Wert1 Wert2 C4 Liste   =Status

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Nach dem Öffnen der Datei und bei aktivierten Makros sieht es so aus:

Arbeitsblatt mit dem Namen 'Tabelle1'   A B C 2 Datum Termine Status 3 29.05.2017     4   S. Wendo erledigt 5   Team erledigt 6   L. T Handball erledigt 7   Einkauf dringend 8   LJ. Logo erledigt 9   L. TK. Mutter-ging keiner dran offen 10   J. Waschtag erledigt 11   J.Montag von der schule abgemeldet erledigt 12 30.05.2017     13   Einkauf dringend 14   L. TK. Mutter-ging keiner dran offen
Name Bezug Status =Parameter!$A$2:$A$4	Zelle Gültigkeitstyp Operator Wert1 Wert2 C4 Liste   =Status   C13 Liste   =Status   C14 Liste   =Status

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Die Farben werden nach Auswahl des Status automatisch gesetzt.
In der Spalte Staus ist in Zeile 4 die Datengültigkeit eingerichtet. Von dort wird die Gültigkeit kopiert und bei neue Einträgen in Folgezeilen eingefügt.

Folgender Code befindet sich im Modul DieseArbeitsmappe:

Code:

Private Sub Workbook_Open()
Dim i As Long, j As Long
Dim lngErste As Long, lngZ As Long
Dim daDatum As Date

With Sheets("Tabelle1")
  daDatum = Application.Max(.Columns("A"))
  If daDatum < Date Then
    lngErste = Application.Match(CLng(daDatum), Columns("A"), 0)
    lngZ = .Cells(.Rows.Count, 2).End(xlUp).Row
    On Error GoTo fehler
    Application.EnableEvents = False
    Application.ScreenUpdating = False
    .Cells(lngErste, 1).Resize(, 3).Copy
    .Cells(lngZ + 1, 1).PasteSpecial xlPasteFormats
    .Cells(lngZ + 1, 1) = Date
    For i = lngErste + 1 To lngZ
      If .Cells(i, 3).Value = "offen" Or .Cells(i, 3).Value = "dringend" Then
        .Cells(i, 2).Resize(, 2).Copy .Cells(lngZ + 2 + j, 2)
        j = j + 1
      End If
    Next i
  End If
End With

fehler:
  Application.EnableEvents = True
  Application.ScreenUpdating = True
  If Err Then MsgBox "Fehler: " & Err.Number & vbLf & vbLf & Err.Description
End Sub

Und im Modul der Tabelle befindet sich dieser Code:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)

 If Target.Column = 1 Then
   If Target.Count > 1 Then
     If Application.CountA(Selection) = 0 Then Selection.Interior.ColorIndex = xlNone
   End If
 End If

 If Target.Column = 2 And Target.Row > 4 Then
   If Target.Count = 1 Then
     If Target <> "" Then
       Application.EnableEvents = False
       Cells(4, 3).Copy
       Target.Offset(, 1).PasteSpecial xlPasteValidation
       Application.EnableEvents = True
     End If
   Else
     If Application.CountA(Selection) = 0 Then Selection.Interior.ColorIndex = xlNone
   End If
 End If

 If Target.Column = 3 Then
   Select Case Target
     Case "erledigt"
       Target.Offset(, -1).Resize(, 2).Interior.ColorIndex = 6
     Case "offen"
       Target.Offset(, -1).Resize(, 2).Interior.ColorIndex = 44
     Case "dringend"
       Target.Offset(, -1).Resize(, 2).Interior.ColorIndex = 3
     Case Else
       Target.Offset(, -1).Resize(, 2).Interior.ColorIndex = xlNone
    End Select
 End If
End Sub

Das Ganze ist in folgender Beispielmappe eingearbeitet:


  Aufgabenverwaltung.xlsm (Größe: 21,03 KB / Downloads: 1)