Index Formel Fehler

[Thomas78]

Hallo liebes Forum,

anbei hoffentlich ein letztes Mal meine aktuelle Datei.

Ich habe nun ein Problem im Blatt "Daten"

Hier habe ich verschiedene Ranglisten erstellt die mir zur Fütterung einer Userform dienen.

Am Beispiel Termine Mitarbeiter BG nächste 30 Tage (L:N) möchte ich mein Problem erklären.
In Spalte L hole ich mir das kleinste Datum innerhalb der nächsten 30 Tage, in Spalte M den entsprechenden Mitarbeiternamen dazu. Diese Formeln funktionieren bisher einwandfrei (oder sieht jemand von euch ein Problem das mir entgangen ist?).
Die Spalte N ist mein Problem. Wie ihr seht zeigt es mir die ersten Werte einwandfrei an, ab Zeile 12 zeigt es mir #Zahl! an (bzw. es zeigt nichts an da ich den Fehler abfange, nur Zeile 12 habe ich als Fehler belassen).
Ich finde den Fehler in der Formel (oder wo auch immer) einfach nicht.

Kann mir jemand von euch bitte nochmal helfen?

Vielen Dank und schöne Grüße

Thomas

[neopa]

Hallo Thomas,

in N5:

Code:

=WENN([@Startdatum]="";"";(INDEX(Termine!$3:$3;AGGREGAT(15;6;SPALTE(Termine!$E$3:$F$3)/
(Termine_Mitarbeiter[[#Alle];[Spalte2]:[Spalte3]]=[@Startdatum])/(Termine_Mitarbeiter[[#Alle];[Spalte1]]=[@Mitarbeiter]);1))))

und in L5 konsequenter auch ohne {} und mit AGGREGAT(), so:

Code:

=WENNFEHLER(AGGREGAT(15;6;Termine_Mitarbeiter[[#Alle];[Spalte2]:[Spalte3]]/
(Termine_Mitarbeiter[[#Alle];[Spalte2]:[Spalte3]]<HEUTE()+30)/(Termine_Mitarbeiter[[#Alle];[Spalte2]:[Spalte3]]>0);ZEILE(L1));"")

[Thomas78]

Hallo Werner,

vielen Dank für deine Hilfe!

Die Formel funktioniert, allerdings nicht wenn bei einem Mitarbeiter 2 gleiche Daten in den Spalten stehen. Also z.B. bei Mitarbeiter a in Spalte Unterweisung der 01.11.2017 und in Spalte Führerscheinkontrolle auch der 01.11.2017. Dann zeigt es mir immer Unterweisung an.



Schöne grüße Thomas

[neopa]

Hallo Thomas,

... dann in N5:

=WENN([@Startdatum]="";"";(INDEX(Termine!$3:$3;AGGREGAT(15;6;SPALTE(Termine!$E$3:$F$3)/
(Termine_Mitarbeiter[[#Alle];[Spalte2]:[Spalte3]]=[@Startdatum])/(Termine_Mitarbeiter[[#Alle];[Spalte1]]=[@Mitarbeiter]);ZÄHLENWENN(M$5:M5;M5)))))

[Thomas78]

Hallo Werner,

nochmal danke, aber damit bekomme ich den gleichen Fehler wie mit meiner ursprünglichen Formel...

Aber immer erst ab Zeile 12, komisch. Noch ne Idee woran das liegen kann?

Schöne Grüße

Thomas

[neopa]

Hallo Thomas,

sorry, ich hatte vorhin nicht getestet.

Es muss natürlich dann in N2 so lauten:

=WENN([@Startdatum]="";"";(INDEX(Termine!$3:$3;AGGREGAT(15;6;SPALTE(Termine!$E$3:$F$3)/
(Termine_Mitarbeiter[[#Alle];[Spalte2]:[Spalte3]]=[@Startdatum])/(Termine_Mitarbeiter[[#Alle];[Spalte1]]=[@Mitarbeiter]);ZÄHLENWENNS(M$5:M5;M5;L$5:L5;L5)))))

[Thomas78]

Hallo Werner,

vielen Dank jetzt funktionierts einwandfrei !!!


Thomas