In einer Tabelle nach mehreren Stichwörtern suchen

[PhilippRoth]

Hallo zusammen,

folgendes Problem:

Tabelle 1:
Name der Opportunity
Value
etc.
etc.
Kategorie (leer)

Tabelle 2:
Stichwort
Kategorie

Gibt es eine Möglichkeit den Namen der Opportunities zu prüfen, ob dieser eines der Stichwörter entält? Wenn ja. soll die entsprechnde Kategorie, welche dem Stichwort zugeordnet ist, dem Opportunity Name zugeordnet werden.
Anbei ein Beispiel in einer Excel.
Danke euch allen!

[shift-del]

Hallo

Code:

=VERWEIS(42;1/ZÄHLENWENN([@[Opp Name]];"*"&Table2[Stichwort]&"*");Table2[Zuordnung])

[PhilippRoth]

Hi shift-del,

danke für die schnelle Antwort, bekomme es aber irgendwie damit nicht hin...
Wieso ist der Verweis Wert 42?
Könntest du die Formel bitte in mein Beispiel einfügen, vielleicht verstehe ich es dann...

Danke :)

[shift-del]

Hallo Philipp

Was bedeutet "bekomme es aber irgendwie nicht hin"'?
Wie bist du vorgegangen?'

Könntest du die Formel bitte in mein Beispiel einfügen, vielleicht verstehe ich es dann...

Kommst du dann mit deinem Rechner bei mir vorbei? Anreise und Übernachtung musst du aber selber zahlen.

[Jockel]

Hallo, ist bei dir der Haken gesetzt bei "Tabellennamen in Formeln benutzen" (bei mir nicht)..? Die Formel ließe sich doch auch dann anpassen... ... alternativ ginge auch..:

Code:

=WENNFEHLER(INDEX($E$2:$E$4;AGGREGAT(15;6;ZEILE($D$2:$D$4)-1/ISTZAHL(SUCHEN($D$2:$D$4;A2));1));"")

[PhilippRoth]

Hallo zusammen

@shift-del
Ich habe deine Formel eingegeben und versucht Sie zu verstehen, leider konnte ich nicht herausfinden was du mit der 42 in deiner Formel bezweckst und leider bekam ich nur eine Error Meldung mit dieser Formel.
=VERWEIS(42;1/ZÄHLENWENN([@[Opp Name]];"*"&Table2[Stichwort]&"*");Table2[Zuordnung])

Ich habe in meinem ersten Post die Beispieldatei angehängt, meine Frage war ob du die Formel dort einfügen kannst um zu prüfen ob es funktioniert und dann die Beispieldatei wieder hochladen könntest ;).

@Jockel
Bei deiner Formel bekomme ich keine Fehlermeldung aber leider auch kein Ergebnis... das Ergebnis ist eine leere Zelle :/
Habe anbei nochmals meine Beispieldatei mit deiner Formel. Vielleicht kannst du den Fehler finden, ich schaffe es leider nicht...

Danke :)

[shift-del]

leider bekam ich nur eine Error Meldung mit dieser Formel.

Welche Error Meldung?

Bei deiner Formel bekomme ich keine Fehlermeldung aber leider auch kein Ergebnis... das Ergebnis ist eine leere Zelle :/

Du hast nicht Jockels Formel benutzt sondern sie so verändert dass sie falsche Ergebnisse liefert.

[Jockel]

Hallo, also auf meinem Rechner kommen bei deiner Datei beide Male die (gleichen) korrekten Ergebnisse mit der Formel von Detlef und mit meiner Formel..:

Arbeitsblatt mit dem Namen 'Sheet1 (3)'
	A	B	C	D	E
1	Opp Name	Zuordnung		Stichwort	Zuordnung
2	Blala Hadoop Blala	Gruppe 1		Hadoop	Gruppe 1
3	Blabla Big Data Blabla	Gruppe 2		Big Data	Gruppe 2
4	Bla bla Vertica Blabla	#NV		Verica	Gruppe 1
5	Blabla Big Data Blabla	Gruppe 2
6	Blabla Big Data Blabla	Gruppe 2

Zelle	Formel
B2	=VERWEIS(42;1/ZÄHLENWENN(A2;"*"&$D$2:$D$4&"*");$E$2:$E$4)

und..:

Arbeitsblatt mit dem Namen 'Sheet1'
	A	B	C	D	E
1	Opp Name	Zuordnung		Stichwort	Zuordnung
2	Blala Hadoop Blala	Gruppe 1		Hadoop	Gruppe 1
3	Blabla Big Data Blabla	Gruppe 2		Big Data	Gruppe 2
4	Bla bla Vertica Blabla			Verica	Gruppe 1
5	Blabla Big Data Blabla	Gruppe 2
6	Blabla Big Data Blabla	Gruppe 2

Zelle	Formel
B2	=WENNFEHLER(INDEX($E$2:$E$4;AGGREGAT(15;6;ZEILE($D$2:$D$4)-1/ISTZAHL(SUCHEN($D$2:$D$4;A2));1));"")

[PhilippRoth]

Hallo ihr beiden,

ich hatte bei der Formel von Detlef eine Klammer vergessen, meine eigene Dummheit. Es funktioniert jetzt, danke.
Ich muss aber sagen, dass ich die Formel noch nicht ganz durchschaue.. Könntest du Sie bitte erklären? Danke!

@Jockel
ich weiß nicht, was ich bei deiner Formel falsch mache, aber irgndwie kommt immer noch einfach eine leere Zeile raus.
Habe die englische Version, habe ich ein Übertragungsfehöer gemacht?

Hier meine Formel:

Code:

=IFERROR(INDEX($E$2:$E$4;AGGREGATE(15;6;ROW($D$2:$D$4)-1/ISNUMBER(SEARCH($D$2:$D$4;A2));));"")

LG

[Jockel]

Hallo,

@Jockel
ich weiß nicht, was ich bei deiner Formel falsch mache, aber irgndwie kommt immer noch einfach eine leere Zeile raus.
Habe die englische Version, habe ich ein Übertragungsfehöer gemacht?
...
LG

Hallo, mir fällt auf, dass du das Argument k wegelassen hast... (also die 1) Sie müßte so lauten...:

Code:

=IFERROR(INDEX($E$2:$E$4;AGGREGATE(15;6;ROW($D$2:$D$4)-1/ISNUMBER(SEARCH($D$2:$D$4;A2));1));"")