Fortlaufende Nummer und Zeitstempel setzen

[tomcat]

Hi Leute,

ich benötige eine fortlaufende Nummerierung in Zellen A15:A1003 beginnend mit "0001" wenn in Zellen B15:G1003 ein wert eingetragen wird.

Die Funktion: A15 =WENN(B15&C15&D15&E15&F15&G15="";"";"0001")

Leider kann ich keine Formel in dieser Zelle nutzen, da ich einen Zeitstempel in den Zellen J15:J1003 eintragen lassen möchte sobald die Zellen A15:A1003 gefüllt sind.

Sollte jetzt ein wert aus den Zellen B15:G1003 gelöscht wird sollen auch die Zellen A15:A1003 und J15:J1003 wieder geleert werden



Kann mir hier jemand bitte helfen?

[{Boris}]

Hi,

einen seriösen Zeitstempel bekommst Du nur mit VBA. Wäre das OK für Dich?

[tomcat]

Das wäre mir sehr recht! Danke

[{Boris}]

OK, dann aber noch ein paar Fragen:

Sollte jetzt ein wert aus den Zellen B15:G1003 gelöscht wird sollen auch die Zellen A15:A1003 und J15:J1003 wieder geleert werden

Wann soll was genau passieren? Sobald irgendeine Zelle (in der entsprechenden Zeile in B:G) gelöscht wird, soll der Zeitstempel erneuert werden? Was ist, wenn man einen bestehenden Eintrag nicht löscht sondern ändert / überschreibt? Was soll dann passieren? Und wie soll sich die Durchnummerierung in Spalte A verhalten: Nummer vergeben, sobald irgendeine Zelle in der entsprechenden Zeile in B:G gefüllt ist? Und erst wieder verschwinden, wenn alle Zellen in der Zeile leer sind?

[tomcat]

Sobald irgendeine Zelle (in der entsprechenden Zeile in B:G) gelöscht wird, soll der Zeitstempel erneuert werden? Was ist, wenn man einen bestehenden Eintrag nicht löscht sondern ändert / überschreibt? Was soll dann passieren?

Angenommen wir reden jetzt von Zeile 15 dann soll sobald kein Wert mehr in B15:G15 steht sollen auch A15 und J15 geleert werden. Sollte jetzt ein Wert in B15:G15 geändert werden soll ein neuer Zeitstempel errechnet werden.

Und wie soll sich die Durchnummerierung in Spalte A verhalten: Nummer vergeben, sobald irgendeine Zelle in der entsprechenden Zeile in B:G gefüllt ist? Und erst wieder verschwinden, wenn alle Zellen in der Zeile leer sind?

sobald irgendeine Zelle im Bereich B15:G15 einen Wert besitzt soll in A15 "0001" stehen. 

Und erst wieder verschwinden, wenn alle Zellen in der Zeile leer sind?

Wenn im Bereich B15:G15 KEIN Wert ist dann soll auch nicht nummeriert werden.



Was ich vergessen habe zu sagen ich brauch einen Zeitstempel mit dem Format:  dd.MM.yyyy HH:mm:ss

[{Boris}]

Hi,

Spalte A formatierst Du benutzerdefiniert mit 0000, Spalte J mit TT.MM.JJJJ hh:mm:ss

Da es um einiges aufwändiger wird, wenn man auch Mehrfachselektionen prüfen muss, habe ich diese jetzt auf eine einzelne Zelle eingeschränkt.
Musst mal sagen, ob das für Dich praktikabel ist.

Der gesamte Code gehört in das Codemodul der entsprechenden Tabelle:

Code:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo ERR_EXIT
If Not Intersect(Target, Range("B15:G1003")) Is Nothing Then
    With Target
        Application.EnableEvents = False
        If WorksheetFunction.CountA(Cells(.Row, 2).Resize(1, 6)) = 0 Then
            Cells(.Row, 1).ClearContents: Cells(.Row, 10).ClearContents
        Else
            Cells(.Row, 10) = Now
            Cells(.Row, 1) = .Row - 14
        End If
    End With
End If
ERR_EXIT:
Application.EnableEvents = True
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
On Error GoTo ERR_EXIT
With Target
    If .Count > 1 Then
        If Not Intersect(Target, Range("B15:G1003")) Is Nothing Then
            Application.EnableEvents = False
            Target(1, 1).Select
        End If
    End If
End With
ERR_EXIT:
Application.EnableEvents = True
End Sub

[tomcat]

Hi Boris 

Vielen Dank die Funktionen laufen bestens!!!

---

Hi Boris jetzt muss ich doch nochmal revidieren sorry...

Soweit funktioniert alles bestens doch wenn ich die Zellen B15:G15 leere werden Zelle A15 und J15 nicht geleert

[{Boris}]

Hi,

kann ich nicht nachvollziehen. Lad doch mal bitte die Mappe hoch.

[tomcat]

Guten Morgen Boris,

also ich hab mir jetzt bisschen mehr Zeit genommen um das ganze zu Prüfen.

Also das Arbeitsblatt wird aktualisiert (also muss ich meine vorherige Aussage zurück nehmen SORRY   )


Wäre es generell möglich auf Mehrfachselektion zu prüfen? Es ist zwar nicht sooooo wichtig aber es wäre natürlich besser.

[{Boris}]

Hi,

prüfen kann man auf alles - aber um es "wasserdicht" zu machen, braucht es halt einiges mehr an Programmieraufwand, zumal Dein Eingabebereich mit B15:G1003 auch recht groß ist.
Hier gilt - wie so oft in der Programmierung: Kleiner Wunsch, großer Aufwand.
Wenn Du Deine Datei mal hochlädst, dann schau ich mal.