Dieses Forum nutzt Cookies
Dieses Forum verwendet Cookies, um deine Login-Informationen zu speichern, wenn du registriert bist, und deinen letzten Besuch, wenn du es nicht bist. Cookies sind kleine Textdokumente, die auf deinem Computer gespeichert werden. Die von diesem Forum gesetzten Cookies werden nur auf dieser Website verwendet und stellen kein Sicherheitsrisiko dar. Cookies aus diesem Forum speichern auch die spezifischen Themen, die du gelesen hast und wann du zum letzten Mal gelesen hast. Bitte bestätige, ob du diese Cookies akzeptierst oder ablehnst.

Ein Cookie wird in deinem Browser unabhängig von der Wahl gespeichert, um zu verhindern, dass dir diese Frage erneut gestellt wird. Du kannst deine Cookie-Einstellungen jederzeit über den Link in der Fußzeile ändern.

[Excel] Bereichsnamen - Teil 3 - Navigation / Datenabrufe
#1
Tabellennavigation / Datenabfragen

Ich habe hier eine kleine Mitarbeitertabelle (MAT) erstellt und den Bereich entsprechend benannt.
In den folgenden Beispielen greife ich auf unterschiedliche Art und Weise auf die einzelnen Felder
dieser Tabelle zurück.
An dieser Stelle möchte ich auch gleich darauf hinweisen, dass bei den Mitarbeitern natürlich auch
Doppelungen auftreten können . Das führt zu Problemen bei der korrekten Auswahl.
Für eine eindeutige Auswahl wären weitere Angaben nötig - idealerweise Personalnummern.

Arbeitsblatt mit dem Namen 'Daten'
 ABCDE
2NameVornameGeburtstag MAT
3MüllerGerd02.02.2012  
4MeierMarion03.03.2013  
5SchulzeHorst04.04.2014  
Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

Beispiel 4
Gezielte Abfragen

In diesen beiden Abfragen hole ich konkret die Vornamen zu dem in der links benachbarten Zelle eingetragenen
Familiennamen. Ich verwende hier einmal den SVERWEIS und einmal den VERWEIS kombiniert mit INDEX.
=SVERWEIS(Daten!I13;_5_MAT;2;0)
=VERWEIS(2;1/(INDEX(_5_MAT;;1)=A7);INDEX(_5_MAT;;2))
mit den Namen _4_Vorname_S und _4_Vorname_V

Sofern Marion Meier einen der beiden Herren heitratet und beide den gleichen Familiennamen führen,
wird das auch im Ergebnis der Abfragen deutlich - probiert es einfach mal aus.
(Anmerkung: Auch wenn Gerd und Horst so zueinander finden, kann man es sehen :-)

Arbeitsblatt mit dem Namen 'Daten'
 AB
12MüllerGerd
13MüllerGerd

NameBezug
_4_Vorname_S=SVERWEIS(Daten!XFD12;_5_MAT;2;0)
_4_Vorname_V=VERWEIS(2;1/(INDEX(_5_MAT;;1)=Daten!XFD12);INDEX(_5_MAT;;2))

ZelleFormel
B12=_4_Vorname_S
B13=_4_Vorname_V
Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

Beispiel 5
Flexible Abfragen

Um flexibel bestimmte Mitarbeiterdaten abrufen zu können, habe ich mir eine Auswahl der Tabellenspalten
zusammengestellt. Dazu verwende ich die Gültigkeit und beziehe mich auf die erste Zeile der MAT:
=INDEX(_5_MAT;1;)
Ich kann nun entsprechend der Spaltenüberschriften auswählen.
Sofern eine Spalte eingefügt wird, erweitert sich die Auswahl gleich. Auf ein Anfügen einer Spalte würde die
hier gezeigte Lösung nicht reagieren - aber machbar wäre dies auch.

Für die Berechnung der Daten habe ich einen weiteren Namen definiert
=_5_MAT_Auswahl
Auch hier kommt wieder eine Funktion mit VERWEIS und INDEX zum Einsatz.
=VERWEIS(2;1/(INDEX(_5_MAT;;1)=Daten!$A9);INDEX(_5_MAT;;VERGLEICH(Daten!$B9;INDEX(_5_MAT;1;);0)))

Arbeitsblatt mit dem Namen 'Daten'
 ABC
24MüllerGeburtstag02.02.2012

NameBezug
_5_MAT=Daten!$A$2:$C$5
_5_MAT_Auswahl=VERWEIS(2;1/(INDEX(_5_MAT;;1)=Daten!$A24);INDEX(_5_MAT;;VERGLEICH(Daten!$B24;INDEX(_5_MAT;1;);0)))

ZelleFormel
C24=_5_MAT_Auswahl

ZelleGültigkeitstypOperatorWert1Wert2
B24Liste =INDEX(_5_MAT;1;) 
Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Daten'
 BCD
36weitere Formelbeispiele  
37   
38 letzteletzte
39 Zeile inSpalte in
40 Spalte AZeile 2
41bezogen auf245
42ganzes BlattMüllerMAT
43   
44 letzteletzte
45 Zeile vonSpalte von
46 MATMAT
47bezogen auf53
48ganzes BlattSchulzeGeburtstag
49   
50 ersteerste
51 Zeile vonSpalte von
52 MATMAT
53bezogen auf21
54ganzes Blatt  
55   
56 AnzahlAnzahl
57 Zeilen inSpalten in
58 MATMAT
59 43

NameBezug
_5_MAT=Daten!$A$2:$C$5

ZelleFormel
C41=VERWEIS(2;1/(A2:A37<>"");ZEILE(A$2:A$37))
D41=VERWEIS(2;1/(Daten!2:2<>"");SPALTE(Daten!2:2))
C42=VERWEIS(2;1/(A2:A37<>"");A$2:A$37)
D42=VERWEIS(2;1/(Daten!2:2<>"");Daten!2:2)
C47=VERWEIS(2;1/(INDEX(_5_MAT;;1)<>"");ZEILE(_5_MAT))
D47=VERWEIS(2;1/(INDEX(_5_MAT;1;)<>"");SPALTE(INDEX(_5_MAT;1;)))
C48=VERWEIS(2;1/(INDEX(_5_MAT;;1)<>"");INDEX(_5_MAT;;1))
D48=VERWEIS(2;1/(INDEX(_5_MAT;1;)<>"");INDEX(_5_MAT;1;))
C53=ZEILE(_5_MAT)
D53=SPALTE(_5_MAT)
C59=ZEILEN(_5_MAT)
D59=SPALTEN(_5_MAT)
Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg
.      \\\|///      Hoffe, geholfen zu haben.
       ( ô ô )      Grüße, André aus G in T  
  ooO-(_)-Ooo    (Excel 97-2019+365)
Antworten Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste