Excel 2010; Zeilenwerte zusammenfügen

[HelmutHH]

Hallo,

möchte aus 2 vorliegenden Spalten "Firma" und "Hinweis" das Ergebnis in der dritten Spalte erhalten, so dass dort alle Einträge zu einer Firma immer zusammengefasst stehen:

Firma  Hinweis  Ergebnis

1           Haus       Haus, Auto, Baum
1           Auto       Haus, Auto, Baum
1          Baum       Haus, Auto, Baum
2          Auto         Auto
5          Katze        Katze, Pferd
5          Pferd         Katze, Pferd
6          Haus         Haus
7          Sack          Sack
8          Hut            Hut, Blume, Kerze, Nadel, Mütze
8         Blume         Hut, Blume, Kerze, Nadel, Mütze
8         Kerze          Hut, Blume, Kerze, Nadel, Mütze
8         Nadel         Hut, Blume, Kerze, Nadel, Mütze
8         Mütze        Hut, Blume, Kerze, Nadel, Mütze

Wer kann mir helfen, die entsprechende Function zu finden?

Danke!
Gruß
Helmut

[Peter]

Hallo,

kopiere die folgende benutzerdefinierte Funktion in ein allgemeines Modul der Datei:

Code:

Function SummeWennText( _
                        SuchSpalte As Range, _
                        Suchbegriff As String, _
                        TextSpalte As Range, _
                        Optional TrennZeichen As String = "" _
                        ) As String
'http://www.office-loesung.de/ftopic460579_0_0_asc.php
Dim arrS
Dim arrT
Dim i As Long
arrS = SuchSpalte.Value
arrT = TextSpalte.Value
For i = 1 To WorksheetFunction.Min(UBound(arrS, 1), UBound(arrT, 1))
    If arrS(i, 1) = Suchbegriff Then SummeWennText = SummeWennText & TrennZeichen & arrT(i, 1)
Next
SummeWennText = Mid(SummeWennText, Len(TrennZeichen) + 1)
End Function

Der Aufruf in C2 erfolgt mit folgender Formel:

=Summewenntext(A$2:A$14;A2;B$2:B$14;", ")

[lupo1]

Ab xl2016 oder 365 ginge das auch ohne VBA mit TEXTVERKETTEN().