Dynamische Listen - Auswahl von Spalten in einer Tabelle

[bennySB]

Das suchen und Eintragen der Kostenstellen funktioniert, jedoch löscht er aktuell die Kostenstellen nicht raus wenn man den Eintrag aus den Spalten "Auftrag - Bezeichnung" entfernt.
Könnte man das noch irgendwie mit einbauen? Das wäre genial.

Also sowas wie:

Code:

=WENN((ISTTEXT(ODER(H15:H19;H22:H29;I32:I36;I39:I43;I46:I50)));hier der VBA Code;"")

Hier der Code mit den richtigen Spalten.

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim a As Range

If Not Application.Intersect(Target, Range("H15:H19, H22:H29, I32:I36, I39:I43, I46:I50")) Is Nothing And Target.Cells.Count = 1 Then
  If Range("M2") = "Neu-Ulm" Then
    Set a = Sheets("Externe Bezüge").ListObjects("tab_Kostenstellen_NU").ListColumns(1).Range.Find(Target, LookAt:=xlWhole)
      If Not a Is Nothing Then Target.Offset(, 1).Value = a.Offset(, 1).Value
      Set a = Nothing
  Else
      Set a = Sheets("Externe Bezüge").ListObjects("tab_Kostenstellen_PCH").ListColumns(1).Range.Find(Target, LookAt:=xlWhole)
      If Not a Is Nothing Then Target.Offset(, 1).Value = a.Offset(, 1).Value
      Set a = Nothing
  End If
End If
End Sub

[Elex]

Man könnte ja einfach vor dem Drücken auf Entf. beide Zelle markieren.

Aber wenn es muss dann halt so.
Funktioniert aber nur Zeilenweise und nicht für Blöcke. Für Blöcke dann halt Entf. nehmen.

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim a As Range, Stelle As String

If Not Application.Intersect(Target, Range("H15:H19, H22:H29, I32:I36, I39:I43, I46:I50")) Is Nothing Then
  If Target.Cells(1) = "" Then
    Range("L" & Target.Cells(1).Row) = ""
  Else
    Stelle = IIf(Range("M2") = "Neu-Ulm", "tab_Kostenstellen_NU", "tab_Kostenstellen_PCH")
    Set a = Sheets("Externe Bezüge").ListObjects(Stelle).ListColumns(1).Range.Find(Target.Cells(1).Value, LookAt:=xlWhole)
     If Not a Is Nothing Then
       Range("L" & Target.Cells(1).Row) = a.Offset(, 1).Value
       Set a = Nothing
     End If
   End If
End If
End Sub

Gruß Elex

[bennySB]

Ach was erwartest du, das würde ja bedeuten man müsste Leuten mehr Aufwand zuweisen 

Dir aber wirklich vielen vielen Dank.