Datum letzter Freitag im Quartal

[Der Steuerfuzzi]

Ich meine mich zu erinnern, dass die Zuordnung von zweistelligen Jahreszahlen zu den jeweiligen Jahrhunderten in den Windows-Einstellungen (Region oder soähjnlich) zu finden waren ...

[LCohen]

Ja, vermutlich ohne Änderungen in diesen Einstellungen wird der 1.1.1930-31.12.2029 zweistellig ermittelt. Sicherer ist: Nachschauen. Noch sicherer ist: Vierstellig.

Ich bin kein Formelgott und versuche einfach nur, eine Lösung anzubieten.

Das ist ja auch ok so. Mit Formelwissen hat das aber weniger zu tun, als mit Mathematik. Deshalb haben die Excelformler ebensolche einmalig walten lassen. Wenn man sagt: "Kapiere ich nicht", ist das wiederum ok so. Dann muss man sie einfach als Black Box ansehen - oder es eben verständlicher und länger machen.

[snb]

Oder:
wenn in A1: Q1/04

Code:

=DATE(2000+RIGHT(A1;2);3*MID(A1;2;1)+1;0)-(WEEKDAY(DATE(2000+RIGHT(A1;2);3*MID(A1;2;1)+1;0);2)<>5)*(WEEKDAY(DATE(2000+RIGHT(A1;2);3*MID(A1;2;1)+1;0);2)+2)

[Jockel]

Hallo, bei Edgars Formel für den Monatsersten im Quartal ( http://www.clever-excel-forum.de/Thread-...#pid129176) bekomme ich auch nicht zufriedenstellende Ergebnisse ..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Q1/18		01.03.1918	01.03.2018
2	Q2/19		01.06.1919	01.06.2019
3	Q3/20		01.09.1920	01.09.2020
4	Q4/04		01.12.1904	01.12.2004

Zelle	Formel
C1	=DATUM(RECHTS(A1;2);WAHL(TEIL(A1;2;1);3;6;9;12);1)
D1	=ERSETZEN(A1;1;2;1&"/"&WAHL(TEIL(A1;2;1);3;6;9;12))*1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[LCohen]

Hallo Bosko, 

=DATUM(RECHTS(A1;2);TEIL(A1;2;1);1) sollte vermutlich
=DATUM(RECHTS(A1;2);TEIL(A1;2;1)*3;1) heißen (rechnend, wie die Formel dort davor)?

vierstelliges Jahr:
=KÜRZEN((DATUM(RECHTS(A1;4);TEIL(A1;2;1)*3+1;)+1)/7)*7-1 als Threadfragenbeantwortung wäre noch kürzer als Dein
=7*KÜRZEN(DATUM(TEIL(A1;SUCHEN("/";A1)+1;4);TEIL(A1;2;1)*3+1;0)/7)-1
wobei meine Formel den letzten Fr. im Q3/2005 richtig ausrechnet. Bei Dir kommt der 23.9. raus, dem aber noch ein 30.9. folgt. Dito Q1/2006.

2- oder 4stelliges Jahr, nur 2000 bis 2099 gemeint/geschrieben:
=KÜRZEN((DATUM(2000+RECHTS(A1;2);TEIL(A1;2;1)*3+1;)+1)/7)*7-1

MrBurns:
Samstag ist immer der Wochentag, der ohne Rest 7 teilbar ist. Wir suchen den vorhergehenden Freitag. Also zählen wir zum 0. Tag des Folge-Quartals 1 hinzu (das ist dann der 1. des Folge-Q), schrabbeln das mit Samstag Rest 7, und ziehen wieder 1 ab, so dass es nur der 0. Tag des Folgequartals oder einer von 6 Tagen vorher sein kann. Der 0. Tag Folgequartal entspricht dem letzten des Quartals.

Fazit: Ein anderer gesuchter letzter Wochentag im Quartal wäre schwieriger (Formel länger).

[Jockel]

Hallo Bosko, 

=DATUM(RECHTS(A1;2);TEIL(A1;2;1);1) sollte vermutlich
=DATUM(RECHTS(A1;2);TEIL(A1;2;1)*3;1) heißen (rechnend, wie die Formel dort davor)?
...

Hi, den schnappe ich doch gleich auf...:

Code:

=ERSETZEN(A1;1;2;1&"/"&TEIL(A1;2;1)*3)*1

[Jockel]

zu früh gefreut... ... jetzt aber wirklich, bei zwei - oder vierstelliger Jahreszahl..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Q1/02	29.03.2002
2	Q3/2057	28.09.2057
3	Q3/2005	30.09.2005
4	Q4/68	27.12.1968
5	Q3/2068	28.09.2068

Zelle	Formel
B1	=KÜRZEN(((MONATSENDE(ERSETZEN(A1;1;2;1&"/"&TEIL(A1;2;1)*3);0)+1)/7))*7-1

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[snb]

Verbessert:

Code:

=DATE(2000+RIGHT(A4;2);3*MID(A4;2;1)+1;0)+(WEEKDAY(DATE(2000+RIGHT(A4;2);3*MID(A4;2;1)+1;0);2)<>5)*(5-WEEKDAY(DATE(2000+RIGHT(A4;2);3*MID(A4;2;1)+1;0);2))

]

[GMG-CC]

Moin,
da ich hier ja nach wie vor passiv aktiv bin (mitlese und mitunter auch per PM zu helfen versuche) ...

Auch wenn Power Query hier "overdressed" wäre und eine reine Formel-Lösung gewiss besser ist will ich allen PQ-Enthusiasten nicht vorenthalten, dass diese Aufgabenstellung auch mit PQ lösbar ist. Mich  hat das Thema insgesamt gereizt und wenn ich außer vielleicht Gesundheitswesen (wo ja am Quartalsende immer die Abrechnung gemacht werden muss) noch weitergehende und allgemeinere Anwendungsmöglichkeiten wüsste, dann käme das auch in meinen Blog.   
Interesse? Einfach eine Mail oder PM an mich (bitte mit Link auf diese Seite oder eindeutigem Betreff) und ich sende dir/euch (m)eine mögliche Lösung. Ich habe bewusst "Trippelschritte" angewendet, weil der Weg zum Ziel dadurch deutlich besser erkennbar ist.

[Jockel]

Verbessert:

Code:

=DATE(2000+RIGHT(A4;2);3*MID(A4;2;1)+1;0)+(WEEKDAY(DATE(2000+RIGHT(A4;2);3*MID(A4;2;1)+1;0);2)<>5)*(5-WEEKDAY(DATE(2000+RIGHT(A4;2);3*MID(A4;2;1)+1;0);2))

]

Hallo, (verschlimmbessert..?) bei dieser schönen langen Formel müssen wir aber ganz schön lange warten bis wir Q3/99 auswerten können..!!! Selbst wenn man Q3/1999 hinschreibt... also für mich (aber ich bin ja nicht der TE) ein Ausschlusskriterium...