Beim Ausdruck / Speichern als PDF soll Tabellenname als Speichername angeboten werden

[Steffl]

Hallo Daniel,

Code:

Sub SaveAsPDF()
Dim varFilename As Variant
Dim InitialFileName As Variant

Dim k As Long
For k = 22 To 37
If Worksheets("Kunden").Cells(k, 13).Text = "x" Then _
Worksheets("Kunden").Cells(k, 12).Text

InitialFileName = Worksheets("Kunden").Cells(k, 12).Text
varFilename = Application.GetSaveAsFilename( _
InitialFileName = Worksheets("Kunden").Cells(k, 12).Text _
& ".pdf")

'FileFilter:="PDF (*.pdf), *.pdf", _
'Title:="als PDF speichern")

If varFilename <> False Then
ThisWorkbook.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:=varFilename
End If
Next
End Sub

Folgendes steht in den Variablen:

varfilename = Leer
Initialfilename = "Rücklagen"
k = 22

Es wird der Speicherdialog geöffent aber es steht dort als Speichername "False"

du machst hier

Code:

varFilename = Application.GetSaveAsFilename( _
InitialFileName = Worksheets("Kunden").Cells(k, 12).Text _
& ".pdf")

einen Vergleich. Ich finde übrigens eine Verwendung von Parameter als Variablennamen nicht unbedingt als glücklich. Versuche es mal so (ungetestet)

Code:

Sub SaveAsPDF()
   Dim varFilename As Variant
   Dim k As Long
  
   For k = 22 To 37
      If Worksheets("Kunden").Cells(k, 13).Text = "x" Then
         varFilename = Application.GetSaveAsFilename( _
         Worksheets("Kunden").Cells(k, 12).Text _
          & ".pdf")
      'FileFilter:="PDF (*.pdf), *.pdf", _
      'Title:="als PDF speichern")
      
         If varFilename <> False Then
            ThisWorkbook.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=varFilename
         End If
      Else
      End If
   Next
End Sub

[Daniel Albert]

Servus, die varFilename bleibt leer, sprich es wird kein Wert eingetragen. Der Speicher unterl Dialog öffnet sich aber es wird kein Name vorgeschlagen

[Steffl]

Hallo Daniel,

versuchs mal so

Code:

Sub SaveAsPDF()
   Dim varFilename As Variant
   Dim k As Long
  
   For k = 22 To 37
      If Worksheets("Kunden").Cells(k, 13).Text = "x" Then
         varFilename = Application.GetSaveAsFilename( _
         Worksheets("Kunden").Cells(k, 12).Text)
      'FileFilter:="PDF (*.pdf), *.pdf", _
      'Title:="als PDF speichern")
      
         If varFilename <> False Then
            ThisWorkbook.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=varFilename
         End If
      Else
      End If
   Next
End Sub

[Daniel Albert]

Hallo, also das Makro läuft durch und es erkennt auch die angekreuzten Tabellenblätter aber es wird in jeden PDF alle Seiten abgespeichert und nicht nur die welche angekreuzt sind.

KOmisch ist auch das beim erstellen die Meldung kommt: wird veröffentlicht

[Steffl]

Hallo,

Code:

Sub SaveAsPDF()
   Dim varFilename As Variant
   Dim k As Long
  
   For k = 22 To 37
      If Worksheets("Kunden").Cells(k, 13).Text = "x" Then
         varFilename = Application.GetSaveAsFilename( _
         Worksheets("Kunden").Cells(k, 12).Text)
      'FileFilter:="PDF (*.pdf), *.pdf", _
      'Title:="als PDF speichern")
      
         If varFilename <> False Then
            
            Worksheets(Worksheets("Kunden").Cells(k, 12).Text).ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=varFilename
         End If
      Else
      End If
   Next
End Sub

[Daniel Albert]

Genial Stefan, danke funktioniert. EInzige bei den PDF Dateien sind 2 Punkte drin, sprich Unfall..pdf

Ich sehe aber nicht wo der Punkt gesetzt wird im Makro

Sonst läuft es :)

[Steffl]

Hallo Daniel,

EInzige bei den PDF Dateien sind 2 Punkte drin, sprich Unfall..pdf

Ich sehe aber nicht wo der Punkt gesetzt wird im Makro

Wie sehen deine Tabellennamen aus?

[Daniel Albert]

Guten Morgen

So:

Rücklagen    
KTG
Unfall

Den Text zieht sich das Makro ja aus der Tabelle Kunden

[Steffl]

Hallo Daniel,

wenn ich die auskommentierten Parameter wieder einfüge geht es

Code:

Sub SaveAsPDF()
   Dim varFilename As Variant
   Dim k As Long
  
   For k = 22 To 37
      If Worksheets("Kunden").Cells(k, 13).Text = "x" Then
         varFilename = Application.GetSaveAsFilename( _
         Worksheets("Kunden").Cells(k, 12).Text, _
         FileFilter:="PDF (*.pdf), *.pdf", _
         Title:="als PDF speichern")
      
         If varFilename <> False Then
            
            Worksheets(Worksheets("Kunden").Cells(k, 12).Text).ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=varFilename
         End If
      Else
      End If
   Next
End Sub

[Daniel Albert]

Danke, perfekt wäre ich nicht drauf gekommen

Danke