Aus Kreuztabelle einen bestimmten Wert auslesen

[Nuling]

Hallo an alle,

ich bin schon fast am verzweifeln  :22: :22: :22:

Ich habe eine Tabelle aus der ich einen wert auslesen möchte. Die Datei habe ich mit eingefügt.

Mein Problem : Ich möchte aus der Kreuztabelle einen bestimmten Wert auslesen der mir in einem anderen Tabellenblatt angezeigt wird. Ich habe mehrere Suchkriterien die unabhängig voneinander eingegeben werden und in der Kreuztabelle an verschiedenen Positionen stehen. hab schon sehr viel versucht aber leider noch nicht die richtige lösung gefunden. 


  Beispiel Excel.xlsm (Größe: 12,77 KB / Downloads: 9)

die suchkriterien sind : Bauteil ; Orientierung und Typ

danke schonmal im voraus

grüße Lars

[shift-del]

Hallo Lars

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	Orientierung	Bauteil	Typ	Breite
2				b
3				0,00 m	Spalte	Zeile
4	N	AW	II	5,41	3	4
5	N	AF 1	I	#NV	3	#NV
6	O	IW	V	3,28	4	14
7	S	IW	II	3,89	5	11
8	S	AT 1	IV	#NV	5	#NV
9	W	IW	III	4,91	6	12
10			IV	#NV	#NV	#NV

Zelle	Formel
D4	=INDEX(Kreutztabelle!$1:$1048576;F4;E4)
E4	=VERGLEICH(A4;Kreutztabelle!$1:$1;0)
F4	=VERWEIS(42;1/(Kreutztabelle!$A$3:$A$20=B4)/(Kreutztabelle!$B$3:$B$20=C4);ZEILE(Kreutztabelle!$A$3:$A$20))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo, oder mit AGGREGAT() ..:

Code:

=WENNFEHLER(INDEX(Kreutztabelle!$C$3:$F$20;AGGREGAT(15;6;ZEILE(Kreutztabelle!$A$1:$A$18)/((Kreutztabelle!$A$3:$A$20=B4)*(Kreutztabelle!$B$3:$B$20=C4));1);VERGLEICH(A4;Kreutztabelle!$C$1:$F$1;0));"")

[snb]

Arrrayformel

PHP-Code:

=INDEX(Kreutztabelle!$A$1:$F$20;MATCH(B5&C5;Kreutztabelle!$A$1:$A$20&Kreutztabelle!$B$1:$B$20;0);MATCH(A5;Kreutztabelle!$A$1:$F$1;0);1)