Ankunft nach Monat tracken

[GuruAD]

Hallo,
ich möchte tracken in welchem Monat etwas reingekommen ist. Wie im Bsp im Anhang, im Main sheet sieht man verschiedene Artikel.

Bsp erster Name AAA. 250 Stück sind da.
Rückwärts kucken: wie viel ist in Mar gekommen. Wenn mehr als was da ist, dann ist alles was da ist aus Mar.
Wenn weniger, dann die Mar Menge rein. In diesem Bsp 230.
Dann wird Feb geschaut. Wie viel ist gekommen. In diesem Bsp 40. Aber nur noch 20 die getrackt werden, dann sind diese offensichtlich in Feb gekommen.
Damit egal was in Jan, Dec etc steht, bleiben diese bei 0.

Bsp ist im Anhang.  

  Bsp.xlsx (Größe: 11,6 KB / Downloads: 9)

Dnake allen für die Hilfe.
Gruß

[HKindler]

Hi,

C2: =MIN($B2;XVERWEIS($A2;'Quelle Mar'!$A:$A;'Quelle Mar'!$B:$B;0))
D2: =MIN($B2-C2;XVERWEIS($A2;'Quelle Feb'!$A:$A;'Quelle Feb'!$B:$B;0))
E2: =MIN($B2-C2-D2;XVERWEIS($A2;'Quelle Jan'!$A:$A;'Quelle Jan'!$B:$B;0))

Aber du solltest dringen über eine geeignete Tabellenstruktur nachdenken. Statt den vielen "Quelle xxx" Blättern, solltest du ein Blatt verwenden, das die Spalten "Model", "Qty" und "Date" hat. Dann könntest du alle Excel-Funktionalitäten gezielt nutzen.

[GuruAD]

Hi, danke dir.

Angenommen es wäre alles in einem Sheet, und Monate in Spalte C, wie wäre dann die Formel?

Danke dir

[Ego]

Hallo G...,

eine Formel für unterschiedliche Datenblätter erstelle ich nicht.
Wenn du die Ankünfte in eine Tabelle schreibst, ginge es so (siehe Anlage):

=MAX(0;MIN($B3-SUMME($C3:C3);SUMMEWENNS(TabAngekommen[Qty];TabAngekommen[Model];$A3;TabAngekommen[angekommen];D$2)))

ps.
In Helmuts Formeln fehlt noch das Ausschliessen von negativen Werten.  "MAX(0;....)"

pps,
 sorry das MAX(0;...) ist nicht notwendig.
also
=MIN($B3-SUMME($C3:C3);SUMMEWENNS(TabAngekommen[Qty];TabAngekommen[Model];$A3;TabAngekommen[angekommen];D$2))

hab die Datei angepasst.

---

Hallo G...,

wenn du nur eine Formel für alle Monate (auch für den letzten) haben möchtest ginge für C3:

=MIN(2*$B3-SUMME($B3:B3);SUMMEWENNS(TabAngekommen[Qty];TabAngekommen[Model];$A3;TabAngekommen[angekommen];C$2))

[GuruAD]

Hi, das ist schon sehr sehr gut. Danke dafür.
Frage: was wenn AAA in Jan mehrfach vorkommt und die Formel die Summe beachten muss?

Vielen Dank und schönen Abend

[BoskoBiati]

Hi,

ich frage mich eigentlich nur, wo die 230 herkommen?

Code:

=MIN(B2;SUMMEWENN('Quelle Mar'!$A:$A;$A2;'Quelle Mar'!$B:$B))
=MIN(B2-C2;SUMMEWENN('Quelle Feb'!$A:$A;$A2;'Quelle Feb'!$B:$B))
=MIN(B2-C2-D2;SUMMEWENN('Quelle Jan'!$A:$A;$A2;'Quelle Jan'!$B:$B))

[Ego]

Hallo G...,

Wenn du Summewenns nicht kennst, kannst du es in der Datei ja ausprobieren.