Alternativen: Summe oder Buchstabe

[RPP63]

Moin!
Ich ersuche um eure geschätzte Hilfe! ;)
Zunächst: Die Formeln sind erheblich umfangreicher, ich konnte mein Problem aber "erfolgreich" herunterbrechen.

Ziel:
Wenn in einer Spalte mindestens eine Zahl steht, benötige ich die Summe aller Zahlen der Spalte.
Steht in dieser Spalte keine Zahl, so soll der erste String von oben ausgegeben werden.
Dies erreiche ich bislang mit folgender Formel:
=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH("*";A1:A6;0)))

	A	B
1	90
2	120
3		K
4	X
5		X
6	180
7	390	K

Zelle	Formel
A7	=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH("*";A1:A6;0)))
B7	=WENN(SUMME(B1:B6);SUMME(B1:B6);INDEX(B1:B6;VERGLEICH("*";B1:B6;0)))

Problem:
Mittlerweile werden die Werte in den Zeilen 1:6 per Formel übergeben.
Entweder Zahl oder Leerstring ""
Der Index(Vergleich()) mit dem Asterisk * findet jetzt aber nicht wie gewünscht den ersten "richtigen" Text, sondern den ersten Leerstring:

	C
1
2
3	K
4
5
6
7

Zelle	Formel
C1	=""
C2	=""
C7	=WENN(SUMME(C1:C6);SUMME(C1:C6);INDEX(C1:C6;VERGLEICH("*";C1:C6;0)))

Wer hilft mir auf die Sprünge?
Zusätzliche Prüfung auf Länge?
Momentan fällt mir nix ein … 

Edit: Habe die Winz-Datei mal angehängt.

Gruß Ralf

[LCohen]

(aus meiner Autofilter-Formel) ungetestet und Datei nicht geöffnet:
=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH(WAHR;INDEX(A1:A6<>"";);0)))

ab 2007 auch möglich (eine Berechnung weniger):
=WENNFEHLER(1/(1/SUMME(A1:A6));INDEX(A1:A6;VERGLEICH(WAHR;INDEX(A1:A6<>"";);0)))

Null und Summe Null (z.B. 2-2+2-2) gelten nicht als Zahlen.

[WillWissen]

Hi,

LCohens Formel funktioniert auch nicht. Der Grund: du hast irgendwo in der Spalte ein Leerzeichen drin. Lösche mal deine Spalte C und trage einen neuen Wert ein; es geht!

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	90
2	120			z
3		K
4	X		K	b
5		X
6	180			c
7	390	K	K	z

Zelle	Formel
A7	=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH("*";A1:A6;0)))
B7	=WENN(SUMME(B1:B6);SUMME(B1:B6);INDEX(B1:B6;VERGLEICH("*";B1:B6;0)))
C7	=WENN(SUMME(C1:C6);SUMME(C1:C6);INDEX(C1:C6;VERGLEICH("*";C1:C6;0)))
D7	=WENN(SUMME(D1:D6);SUMME(D1:D6);INDEX(D1:D6;VERGLEICH("*";D1:D6;0)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Frogger1986]

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
7	390	K	K

Zelle	Formel
A7	=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH("?";A1:A6;0)))
B7	=WENN(SUMME(B1:B6);SUMME(B1:B6);INDEX(B1:B6;VERGLEICH("?";B1:B6;0)))
C7	=WENN(SUMME(C1:C6);SUMME(C1:C6);INDEX(C1:C6;VERGLEICH("?";C1:C6;0)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Mit  "?" Kommt das "K"

[RPP63]

Du bist der Burner!  :19:
Wie kommt man auf INDEX(C1:C6<>"";)
was ja folgendes ergibt:
{FALSCH;FALSCH;WAHR;FALSCH;FALSCH;FALSCH}
Du sprichst von Deiner Filterformel.
Hast Du dazu einen Link?

Gruß Ralf

[RPP63]

Hi,

LCohens Formel funktioniert auch nicht. Der Grund: du hast irgendwo in der Spalte ein Leerzeichen drin.

Doch, doch, sie funktioniert, Günter:

	A	B	C
1	90
2	120
3		K	K
4	X
5		X
6	180
7	390	K	K

Zelle	Formel
C1	=""
C2	=""
A7	=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH(WAHR;INDEX(A1:A6<>"";);0)))
B7	=WENN(SUMME(B1:B6);SUMME(B1:B6);INDEX(B1:B6;VERGLEICH(WAHR;INDEX(B1:B6<>"";);0)))
C7	=WENN(SUMME(C1:C6);SUMME(C1:C6);INDEX(C1:C6;VERGLEICH(WAHR;INDEX(C1:C6<>"";);0)))

Gruß Ralf

[RPP63]

Mit  "?" Kommt das "K"

Mein Danke war Dir gewiss! ;)
Dass der erste String auch aus mehreren Buchstaben bestehen kann, konntest Du nicht wissen.
Scheiß Threaderöffnung; Mea Culpa!

Gruß Ralf

[WillWissen]

Hi Ralf,

sorry, muss dir widerwprechen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	90				0	1
2	120			z	1	1
3		K			0	1
4	X		K	b	1	1
5		X			0	0
6	180			c	0	1
7	390	K
8
9	390	K

Zelle	Formel
E1	=LÄNGE(C1)
F1	=LÄNGE(D1)
A7	=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH("*";A1:A6;0)))
A9	=WENN(SUMME(A1:A6);SUMME(A1:A6);INDEX(A1:A6;VERGLEICH(WAHR;INDEX(A1:A6<>"";);0)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[LCohen]

Nein, muss ich noch machen. Es gab in den letzten 7 Tagen bestimmt 7 Anwendungen davon quer über die Foren, die sich aber alle unterschieden.

Hier ist ein ziemlich komplexes Beispiel:
  180531 Mehrfach-SVERWEIS-Formel mit 2 wahlweisen Kriterienspalten.xlsx (Größe: 9,85 KB / Downloads: 3)

[Jockel]

Hallo, ich werfe (abgewandelt) ein..:

PHP-Code:

=WENNFEHLER(1/(1/SUMME(A1:A6));INDEX(A1:A6;VERGLEICH("*";A1:A6;0))) 


Ich weiß nicht ob die INDEX() Geschichte im VERGLEICH() hier nottut... cool ist's allemal...