Das Clever-Excel-Forum.de - Treffen
... 14.-16. September 2018 im Allgäu ...

Abfrage mit mehreren Bedingungen
#1
hi Zusammen,

ich bin gerade am Verzweifeln.

ich müsste in eine Liste Spalte A nach einem mehrmals vorkommenden Wert filtern und dann innerhalb der Zeile dieser Werte die Größte Zahl (spalte D) herausfinden damit ich am ende Die Bezeichnung (Spalte C)
stehen habe.

die abfrage nach Kgrößte habe ich =INDEX(C:C;VERGLEICH(KGRÖSSTE(D:D;ZEILE(A1));D:D;0);SPALTE(A1))
so gemacht 
allerdings bringt mich die zusätzliche Abfrage nach dem 1 Wert zu verzweiflung 

kann mir bitte wer helfen bitte?

?mage
to top
#2
falls wer ne einfacher Lösung hat gerne!!

=SVERWEIS(KGRÖSSTE(INDIREKT(I2&VERGLEICH($G$1;D:D;0)):INDIREKT(I2&SUMME(ZÄHLENWENN(D:D;G1);VERGLEICH($G$1;D:D;0)));1);INDIREKT(I2&VERGLEICH($G$1;D:D;0)):INDIREKT(J2&SUMME(ZÄHLENWENN(D:D;G1);VERGLEICH($G$1;D:D;0)));3;FALSCH)
to top
#3
(12.02.2016, 17:22)BastianWern schrieb: falls wer ne einfacher Lösung hat gerne!!

Hallo, kannst du mal bitte die (grafischen) Smilies deaktivieren..? Und statt deines Bildchens (d)eine (Beispiel)datei posten..?
cu Jörg eine Rückmeldung wäre ganz reizend XL2003 bis XL2013
to top
#4
Hi Bastian,

kommt das deinem Problem nahe?

Tabelle1

ABCDEFGH
1NrGerichtWerteHilfsspalten E und FSuchwert
2121Seelachs0,97716458121,0002133Suppe
3131Eintopf0,6933801131,0003Kaviar
4131Zweitopf0,83914236131,0004Bratkartoffeln
5132Forelle0,21835133132,0005
6133Bratkartoffeln0,52052232133,00066
7133Kaviar0,58587333133,00077
8133Suppe0,87495303133,00088
9
10
11
12
13
14
15
16
17
18
Formeln der Tabelle
ZelleFormel
E2=WENN(A2+ZEILE(A2)%%>=1;A2+ZEILE(A2)%%;"")
F2=WENNFEHLER(VERGLEICH($G$2+ZEILE(A2)%%;$E$1:$E$8;0);"")
H2=WENNFEHLER(INDEX(C:C;KGRÖSSTE($F$2:$F$8;ZEILE(A1)));"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Hilfsspalten kannst du einfach ausblenden.
Gruß Günter
Misserfolg ist eine Chance, es beim nächsten Mal besser zu machen.
(Henry Ford) http://www.sprueche-zum-nachdenken.eu
to top
#5
Hallo,

ich hätte diese Lösung:

Arbeitsblatt mit dem Namen 'Tabelle2'
 ABCDEF
1Nr GerichtWerteSuchwert 
2121 Seelachs0,9771646133Suppe
3131 Eintopf0,6933801  
4131 Zweitopf0,8391424  
5132 Forelle0,2183513  
6133 Bratkartoffeln0,5205223  
7133 Kaviar0,5858733  
8133 Suppe0,874953  

ZelleFormel
F2=INDEX(C:C;VERGLEICH(MAX(INDEX(D:D;VERGLEICH(E2;A:A;0)):INDEX(D:D;VERGLEICH(E2;A:A;0)+ZÄHLENWENN(A:A;E2)-1));D:D;0))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß Atilla
to top
#6
Hallo,

oder so:

Arbeitsblatt mit dem Namen 'Tabelle2'
 ABCDEFGH
1Nr GerichtWerte  Suchwert 
2121 Seelachs0,97716458  133Suppe
3131 Eintopf0,6933801   Kaviar
4131 Zweitopf0,83914236   Bratkartoffeln
5132 Forelle0,21835133    
6133 Bratkartoffeln0,52052232    
7133 Kaviar0,58587333    
8133 Suppe0,87495303    

ZelleFormel
H2{=INDEX(C:C;VERGLEICH(KGRÖSSTE(WENN((A:A=$G$2);D:D);ZEILE(A1));D:D;0))}
H3{=INDEX(C:C;VERGLEICH(KGRÖSSTE(WENN((A:A=$G$2);D:D);ZEILE(A2));D:D;0))}
H4{=INDEX(C:C;VERGLEICH(KGRÖSSTE(WENN((A:A=$G$2);D:D);ZEILE(A3));D:D;0))}
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

oder, analog zu atillas Formel:


Code:
=INDEX(C:C;VERGLEICH(KGRÖSSTE(INDEX(D:D;VERGLEICH($G$2;A:A;0)):INDEX(D:D;VERGLEICH($G$2;A:A;0)+ZÄHLENWENN(A:A;$G$2));ZEILE(A1));D:D;0))
Gruß
Opa Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
to top
#7
SUPER VIELEN VIELEN DANK EUCH!
to top
#8
Hallo, ich würde das so tun..:

Arbeitsblatt mit dem Namen 'Blatt1'
 ABCDEFG
1Nr GerichtWerte Nr 
2121 Seelachs0,977165 131Zweitopf
3131 Eintopf0,69338   
4131 Zweitopf0,839142   
5132 Forelle0,218351   
6133 Bratkartoffeln0,520522   
7133 Kaviar0,585873   
8133 Suppe0,874953   

ZelleFormel
G2=INDEX(C:C;VERGLEICH(DBMAX(A1:D8;4;F1:F2);D:D;0))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
cu Jörg eine Rückmeldung wäre ganz reizend XL2003 bis XL2013
to top
#9
Hi Jörg,

entweder ich übersehe etwas oder aber deine Formel berechnet nicht richtig die Werte. Ich komme auf dieses Ergebnis, was definitiv falsch ist.

Tabelle1 (2)

ABCDEFG
1NrGerichtWerteSuchwertJörg
2121Seelachs0,977164577131Seelachs
3131Eintopf0,693380104
4131Zweitopf0,839142363
5132Forelle0,218351328
6133Bratkartoffeln0,520522316
7133Kaviar0,585873334
8133Suppe0,874953032
Formeln der Tabelle
ZelleFormel
G2=INDEX(C:C;VERGLEICH(DBMAX(A1:D8;4;F1:F2);D:D;0))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Wo werden die zur ID-Nr. (Spalte A) dazugehörigen Werte aus C geschrieben? Bei Suchwert 131 müssen nach absteigend formatierten Werten aus D (0,69338 und 0,839142) zuerst der Zweitopf und dann der Eintopf auftauchen. Ich habe mal versucht, deine Formel anzupassen, was mir aber nicht gelungen ist.
Gruß Günter
Misserfolg ist eine Chance, es beim nächsten Mal besser zu machen.
(Henry Ford) http://www.sprueche-zum-nachdenken.eu
to top
#10
(14.02.2016, 17:28)WillWissen schrieb: Hi Jörg,

entweder ich übersehe etwas oder aber deine Formel berechnet nicht richtig die Werte. Ich komme auf dieses Ergebnis, was definitiv falsch ist.

Hallo Günter, vielleicht übersehe ich ja was..?

Arbeitsblatt mit dem Namen 'Blatt1'
 ABCDEFGHI
1Nr GerichtWerte Nr   
2121 Seelachs0,977165 131ZweitopfZweitopfZweitopf
3131 Eintopf0,69338     
4131 Zweitopf0,839142     
5132 Forelle0,218351     
6133 Bratkartoffeln0,520522     
7133 Kaviar0,585873     
8133 Suppe0,874953     
9         

ZelleFormel
G2=INDEX(C:C;VERGLEICH(DBMAX(A1:D8;4;F1:F2);D:D;0))
H2=INDEX(C:C;VERGLEICH(KGRÖSSTE(INDEX(D:D;VERGLEICH($F$2;A:A;0)):INDEX(D:D;VERGLEICH($F$2;A:A;0)+ZÄHLENWENN(A:A;$F$2));ZEILE(A1));D:D;0))
I2=INDEX(C:C;VERGLEICH(MAX(INDEX(D:D;VERGLEICH(F2;A:A;0)):INDEX(D:D;VERGLEICH(F2;A:A;0)+ZÄHLENWENN(A:A;F2)-1));D:D;0))
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
cu Jörg eine Rückmeldung wäre ganz reizend XL2003 bis XL2013
to top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste